Gnuplotting

Create scientific plots using gnuplot

gnuplot 4.6


An Interactive Plotting Program
Thomas Williams & Colin Kelley
Version 4.6 organized by: Hans-Bernhard Bröker, Ethan A Merritt, and others
Major contributors (alphabetic order):
Hans-Bernhard Bröker, John Campbell,
Robert Cunningham, David Denholm,
Gershon Elber, Roger Fearick,
Carsten Grammes, Lucas Hart,
Lars Hecking, Péter Juhász,
Thomas Koenig, David Kotz,
Ed Kubaitis, Russell Lang,
Timothée Lecomte, Alexander Lehmann,
Alexander Mai, Bastian Märkisch,
Ethan A Merritt, Petr Mikulík,
Carsten Steger, Shigeharu Takeno,
Tom Tkacik, Jos Van der Woude,
James R. Van Zandt, Alex Woo, Johannes Zellner
Copyright © 1986 - 1993, 1998, 2004 Thomas Williams, Colin Kelley
Copyright © 2004 - 2012 various authors
Mailing list for comments: gnuplot-info@lists.sourceforge.net
Mailing list for bug reports: gnuplot-bugs@lists.sourceforge.net
Web access (preferred): http://sourceforge.net/projects/gnuplot

This manual was originally prepared by Dick Crawford.
Here you see a slightly modified version from the one offered
on the gnuplot documentation site

2012 Version 4.6


Contents

I  Gnuplot
Copyright
Introduction
Seeking-assistance
New features
    New syntax
    Local customization of linetypes
    New plot styles
    Revised polar axes
    New smoothing algorithms
    New time/date handling
    Statistical summary of data
    New or revised terminal drivers
Backwards compatibility
Batch/Interactive Operation
Canvas size
Command-line-editing
Comments
Coordinates
Datastrings
Enhanced text mode
Environment
Expressions
    Functions
        Elliptic integrals
        Random number generator
        Value
    Operators
        Unary
        Binary
        Ternary
    Summation
    Gnuplot-defined variables
    User-defined variables and functions
Fonts
    Cairo (pdfcairo, pngcairo, epscairo, wxt terminals)
    Gd (png, gif, jpeg terminals)
    Postscript (also encapsulated postscript *.eps)
Glossary
Linetypes, colors, and styles
    Colorspec
        Background color
        Linecolor variable
        Rgbcolor variable
    Linestyles vs linetypes
Mouse input
    Bind
        Bind space
    Mouse variables
Plotting
Start-up (initialization)
String constants and string variables
Substitution and Command line macros
    Substitution of system commands in backquotes
    Substitution of string variables as macros
    String variables, macros, and command line substitution
Syntax
    Quote Marks
Time/Date data
II  Plotting styles
Boxerrorbars
Boxes
Boxplot
Boxxyerrorbars
Candlesticks
Circles
Ellipses
Dots
Filledcurves
Financebars
Fsteps
Fillsteps
Histeps
Histograms
    Newhistogram
    Automated iteration over multiple columns
Image
    Transparency
    Image failsafe
Impulses
Labels
Lines
Linespoints
Points
Polar
Steps
Rgbalpha
Rgbimage
Vectors
Xerrorbars
Xyerrorbars
Yerrorbars
Xerrorlines
Xyerrorlines
Yerrorlines
3D (surface) plots
    2D projection (set view map)
III  Commands
Cd
Call
Clear
Do
Evaluate
Exit
Fit
    Adjustable parameters
    Short introduction
    Error estimates
        Statistical overview
        Practical guidelines
    Control
        Control variables
        Environment variables
    Multi-branch
    Starting values
    Tips
Help
History
If
    If-old
Iteration
Load
Lower
Pause
Plot
    Axes
    Binary
        General
        Array
        Record
        Skip
        Format
        Endian
        Filetype
        Avs
        Edf
        Png
        Keywords
        Scan
        Transpose
        Dx, dy, dz
        Flipx, flipy, flipz
        Origin
        Center
        Rotate
        Perpendicular
    Data
        Every
        Example datafile
        Index
        Smooth
        Acsplines
        Bezier
        Csplines
        Sbezier
        Unique
        Frequency
        Cumulative
        Cnormal
        Kdensity
        Special-filenames
        Thru
        Using
        Using_examples
        Pseudocolumns
        Xticlabels
        X2ticlabels
        Yticlabels
        Y2ticlabels
        Zticlabels
        Volatile
    Errorbars
    Errorlines
    Functions
    Parametric
    Ranges
    Iteration
    Title
    With
Print
Pwd
Quit
Raise
Refresh
Replot
Reread
Reset
Save
Set-show
    Angles
    Arrow
    Autoscale
        Parametric mode
        Polar mode
    Bars
    Bind
    Bmargin
    Border
    Boxwidth
    Clabel
    Clip
    Cntrparam
    Color box
    Colornames
    Contour
    Data style
    Datafile
        Set datafile fortran
        Set datafile nofpe_trap
        Set datafile missing
        Set datafile separator
        Set datafile commentschars
        Set datafile binary
    Decimalsign
    Dgrid3d
    Dummy
    Encoding
    Fit
    Fontpath
    Format
        Gprintf
        Format specifiers
        Time/date specifiers
    Function style
    Functions
    Grid
    Hidden3d
    Historysize
    Isosamples
    Key
        Key placement
        Key samples
    Label
    Linetype
    Lmargin
    Loadpath
    Locale
    Logscale
    Macros
    Mapping
    Margin
    Mouse
        Doubleclick
        Mouseformat
        Scrolling
        X11 mouse
        Zoom
    Multiplot
    Mx2tics
    Mxtics
    My2tics
    Mytics
    Mztics
    Object
        Rectangle
        Ellipse
        Circle
        Polygon
    Offsets
    Origin
    Output
    Parametric
    Plot
    Pm3d
        Algorithm
        Position
        Scanorder
        Clipping
        Color_assignment
        Hidden3d
        Interpolate
        Deprecated_options
    Palette
        Rgbformulae
        Defined
        Functions
        Cubehelix
        File
        Gamma correction
        Postscript
    Pointintervalbox
    Pointsize
    Polar
    Print
    Psdir
    Raxis
    Rmargin
    Rrange
    Rtics
    Samples
    Size
    Style
        Set style arrow
        Boxplot
        Set style data
        Set style fill
        Set style fill transparent
        Set style function
        Set style increment
        Set style line
        Set style circle
        Set style rectangle
        Set style ellipse
    Surface
    Table
    Terminal
    Termoption
    Tics
    Ticslevel
    Ticscale
    Timestamp
    Timefmt
    Title
    Tmargin
    Trange
    Urange
    Variables
    Version
    View
        Equal_axes
    Vrange
    X2data
    X2dtics
    X2label
    X2mtics
    X2range
    X2tics
    X2zeroaxis
    Xdata
    Xdtics
    Xlabel
    Xmtics
    Xrange
    Xtics
        Xtics time_data
        Xtics rangelimited
    Xyplane
    Xzeroaxis
    Y2data
    Y2dtics
    Y2label
    Y2mtics
    Y2range
    Y2tics
    Y2zeroaxis
    Ydata
    Ydtics
    Ylabel
    Ymtics
    Yrange
    Ytics
    Yzeroaxis
    Zdata
    Zdtics
    Zzeroaxis
    Cbdata
    Cbdtics
    Zero
    Zeroaxis
    Zlabel
    Zmtics
    Zrange
    Ztics
    Cblabel
    Cbmtics
    Cbrange
    Cbtics
Shell
Splot
    Data-file
        Matrix
        Example datafile
    Grid data
    Splot surfaces
Stats (Statistical Summary)
System
Test
Undefine
Unset
Update
While
IV  Terminal types
Complete list of terminals
    Aed767
    Aifm
    Aqua
    Be
        Command-line_options
        Monochrome_options
        Color_resources
        Grayscale_resources
        Line_resources
    Cairolatex
    Canvas
    Cgi
    Cgm
        Cgm font
        Cgm fontsize
        Cgm linewidth
        Cgm rotate
        Cgm solid
        Cgm size
        Cgm width
        Cgm nofontlist
    Context
        Requirements
        Calling gnuplot from ConTeXt
    Corel
    Debug
    Dumb
    Dxf
    Dxy800a
    Eepic
    Emf
    Emxvga
    Epscairo
    Epslatex
    Epson_180dpi
    Excl
    Fig
    Ggi
    Gif
        Examples
    Gpic
    Grass
    Hp2623a
    Hp2648
    Hp500c
    Hpgl
    Hpljii
    Hppj
    Imagen
    Jpeg
    Kyo
    Latex
    Linux
    Lua
        Lua tikz
    Macintosh
    Mf
        METAFONT Instructions
    Mif
    Mp
        Metapost Instructions
    Next
    Openstep (next)
    Pbm
    Pdf
    Pdfcairo
    Pm
    Png
        Examples
    Pngcairo
    Postscript
        Editing postscript
        Postscript fontfile
        Postscript prologue
        Postscript adobeglyphnames
    Pslatex and pstex
    Pstricks
    Qms
    Qt
    Regis
    Sun
    Svg
    Svga
    Tek40
    Tek410x
    Texdraw
    Tgif
    Tikz
    Tkcanvas
    Tpic
    Vgagl
    VWS
    Vx384
    Windows
        Graph-menu
        Printing
        Text-menu
        Wgnuplot.mnu
        Wgnuplot.ini
    Wxt
    X11
        X11_fonts
        Command-line_options
        Monochrome_options
        Color_resources
        Grayscale_resources
        Line_resources
        X11 pm3d_resources
        X11 other_resources
    Xlib
V  Bugs
Known limitations
External libraries


Part I
Gnuplot

Copyright

   Copyright (C) 1986 - 1993, 1998, 2004, 2007  Thomas Williams, Colin Kelley

Permission to use, copy, and distribute this software and its documentation for any purpose with or without fee is hereby granted, provided that the above copyright notice appear in all copies and that both that copyright notice and this permission notice appear in supporting documentation.

Permission to modify the software is granted, but not the right to distribute the complete modified source code. Modifications are to be distributed as patches to the released version. Permission to distribute binaries produced by compiling modified sources is granted, provided you

 1. distribute the corresponding source modifications from the
  released version in the form of a patch file along with the binaries,
 2. add special version identification to distinguish your version
  in addition to the base release version number,
 3. provide your name and address as the primary contact for the
  support of your modified version, and
 4. retain our contact information in regard to use of the base
  software.
Permission to distribute the released version of the source code along with corresponding source modifications in the form of a patch file is granted with same provisions 2 through 4 for binary distributions.

This software is provided "as is" without express or implied warranty to the extent permitted by applicable law.

     AUTHORS
     Original Software:
        Thomas Williams,  Colin Kelley.
     Gnuplot 2.0 additions:
        Russell Lang, Dave Kotz, John Campbell.
     Gnuplot 3.0 additions:
        Gershon Elber and many others.
     Gnuplot 4.0 additions:
        See list of contributors at head of this document.

Introduction

Gnuplot is a portable command-line driven graphing utility for Linux, OS/2, MS Windows, OSX, VMS, and many other platforms. The source code is copyrighted but freely distributed (i.e., you don't have to pay for it). It was originally created to allow scientists and students to visualize mathematical functions and data interactively, but has grown to support many non-interactive uses such as web scripting. It is also used as a plotting engine by third-party applications like Octave. Gnuplot has been supported and under active development since 1986.

Gnuplot supports many types of plots in either 2D and 3D. It can draw using lines, points, boxes, contours, vector fields, surfaces, and various associated text. It also supports various specialized plot types.

Gnuplot supports many different types of output: interactive screen terminals (with mouse and hotkey input), direct output to pen plotters or modern printers, and output to many file formats (eps, emf, fig, jpeg, LaTeX, pdf, png, postscript, ...). Gnuplot is easily extensible to include new output modes. Recent additions include interactive terminals based on wxWidgets (usable on multiple platforms), and Qt. Mouseable plots embedded in web pages can be generated using the svg or HTML5 canvas terminal drivers.

The command language of gnuplot is case sensitive, i.e. commands and function names written in lowercase are not the same as those written in capitals. All command names may be abbreviated as long as the abbreviation is not ambiguous. Any number of commands may appear on a line, separated by semicolons (;). Strings may be set off by either single or double quotes, although there are some subtle differences. See syntax (p. 51) and quotes (p. 52) for more details. Examples:

     load "filename"
     cd 'dir'

Commands may extend over several input lines by ending each line but the last with a backslash (\). The backslash must be the last character on each line. The effect is as if the backslash and newline were not there. That is, no white space is implied, nor is a comment terminated. Therefore, commenting out a continued line comments out the entire command (see comments (p. 24)). But note that if an error occurs somewhere on a multi-line command, the parser may not be able to locate precisely where the error is and in that case will not necessarily point to the correct line.

In this document, curly braces ({}) denote optional arguments and a vertical bar (|) separates mutually exclusive choices. Gnuplot keywords or help topics are indicated by backquotes or boldface (where available). Angle brackets (<>) are used to mark replaceable tokens. In many cases, a default value of the token will be taken for optional arguments if the token is omitted, but these cases are not always denoted with braces around the angle brackets.

For built-in help on any topic, type help followed by the name of the topic or help ? to get a menu of available topics.

The new gnuplot user should begin by reading about plotting (if in an interactive session, type help plotting).

See the simple.dem demo, also available together with other demos on the web page

http://www.gnuplot.info/demo/

Gnuplot can be started from a command line or from an icon according to the desktop environment. Running it from command line can take the syntax

     gnuplot {OPTIONS} file1 file2 ...
where file1, file2, etc. are input file as in the load command. On X11-based systems, you can use
     gnuplot {X11OPTIONS} {OPTIONS} file1 file2 ...
see your X11 documentation and x11 (p. 310) in this document.

Options interpreted by gnuplot may come anywhere on the line. Files are executed in the order specified, as are commands supplied by the -e option, for example

     gnuplot   file1.in   -e "reset"   file2.in

The special filename "-" is used to force reading from stdin. Gnuplot exits after the last file is processed. If no load files are named, Gnuplot takes interactive input from stdin. See help batch/interactive (p. 22) for more details. The options specific to gnuplot can be listed by typing

     gnuplot --help
See command line options (p. 22) for more details.

In sessions with an interactive plot window you can hit 'h' anywhere on the plot for help about hotkeys and mousing features. Section seeking-assistance will help you to find further information, help and FAQ.

Seeking-assistance

The canonical gnuplot web page can be found at

http://www.gnuplot.info

Before seeking help, please check file FAQ.pdf or the above website for

FAQ (Frequently Asked Questions) list.

If you need help as a gnuplot user, please use the newsgroup

         comp.graphics.apps.gnuplot
We prefer that you read the messages through the newsgroup rather than subscribing to the mailing list which is also available and carries the same set of messages. Instructions for subscribing to gnuplot mailing lists may be found via the gnuplot development website on SourceForge

http://sourceforge.net/projects/gnuplot

The address for mailing to list members is:

         gnuplot-info@lists.sourceforge.net

Bug reports and code contributions should be uploaded to the trackers at

         http://sourceforge.net/projects/gnuplot/support
Please check previous bug reports if the bug you want to report has not been already fixed in a newer version of gnuplot.

A mailing list for those interested in development version of gnuplot is:

         gnuplot-beta@lists.sourceforge.net

When posting a question, please include full details of the gnuplot version, the terminal type, and the operating system you are using. A small script demonstrating the problem may be useful. Function plots are preferable to datafile plots.

New features

This section lists major additions since version 4.4. For a more exhaustive list, see the NEWS file.

New syntax

This version of gnuplot introduces command iteration and block-structured if/else/while/do constructs. See if (p. 89), while (p. 239), and do (p. 78). Simple iteration is possible inside plot or set commands. See iteration (p. 90). General iteration spanning multiple commands is possible using a block construct as shown below. For a related new feature, see the summation (p. 34) expression type. Here is an example using several of these new syntax features:

Fourier Series

Fig. 1 1-1000 term Fourier Series (code to produce this figure)

     set multiplot layout 2,2
     fourier(k, x) = sin(3./2*k)/k * 2./3*cos(k*x)
     do for [power = 0:3] {
         TERMS = 10**power
         set title sprintf("%g term Fourier series",TERMS)
         plot 0.5 + sum [k=1:TERMS] fourier(k,x) notitle
     }
     unset multiplot

It is now possible to select a column of data from a data file by matching a label in the first row of the file. See columnhead (p. 31). For example

     plot for [crop in "Oats Peas Beans"] 'data' using "Year":crop

Local customization of linetypes

You can now customize properties (color, linewidth, point type) of the default sequence of linetypes used in plotting. See set linetype (p. 166). This is normally done in an initialization file, either the system-wide file gnuplotrc or a private file ~/.gnuplot. See initialization (p. 47).

Most terminals now allow you to set an explicit background color for the plot. The special linetype bgnd can be used to draw in this color. See bgnd (p. 41).

New plot styles

See documentation for plot styles boxplot (p. 56), circles (p. 58), ellipses (p. 59), and fillsteps (p. 63).

Revised polar axes

Polar plot mode has been reworked to support additional plot styles. The polar axes can now be drawn and labeled independent of the x and y axes. See set polar (p. 194) and set rrange (p. 196).

New smoothing algorithms

New smoothing algorithms have been added for both 2- and 3-dimensional plots. smooth kdensity and smooth cumulative can be used with plot to draw smooth histograms and cumulative distribution functions. Several new smoothing kernels have been added to dgrid3d for use with splot. See smooth (p. 104) dgrid3d (p. 147).

New time/date handling

Gnuplot now tracks time to millisecond precision. Time formats have been modified to match this. The new built-in function time() returns the current time of day according to the system clock. Example: print the current time to msec precision

    print strftime("%H:%M:%.3S %d-%b-%Y",time(0.0))
    18:15:04.253 16-Apr-2011

Statistical summary of data

The new stats command reads data from a file using the same syntax as the plot or splot commands. Rather than drawing a graph, it prints out a statistical summary of the data contained in the column[s] requested. The resulting statistics min, max, mean, standard deviation, correlation, etc. are also stored in named variables that can be used to compose or modify subsequent plotting commands. See stats (p. 236).

New or revised terminal drivers

The qt driver implements an interactive terminal on top of the Qt graphics layer. It can function either as a window in a full-featured desktop enviroment or as a full-screen application on a Qt-based embedded device. The qt terminal is new and may still have some rough edges.

Two terminal types support web-based interactive display. The HTML5 canvas terminal was introduced in version 4.4. The svg terminal has been extensively revised to include support for mousing and better incorporation of svg plots from gnuplot into larger svg/xml documents.

The canvas terminal driver produces javascript output that draws onto the HTML canvas element of a web page. It can produce either a complete web page containing a single plot, or a script that can be embedded as part of an externally generated HTML document that perhaps contains multiple plots. The embedded plots support browser-side mousing, including zoom/unzoom.

The lua terminal driver creates data intended to be further processed by a script in the lua programming language. At this point only one such lua script, gnuplot-tikz.lua, is available. It produces a TeX document suitable for use with the latex TikZ package. Other lua scripts could be written to process the gnuplot output for use with other TeX packages, or with other non-TeX tools.

set term tikz is shorthand for set term lua tikz. As decribed above, it uses the generic lua terminal and an external lua script to produce a latex document.

The context terminal driver creates output to be further processed by the ConTeXt TeX macro package. To process its output, you additionally require the gnuplot module for ConTeXt available at

http://ctan.org/pkg/context-gnuplot

The epscairo terminal uses the cairo and pango libraries to create encapsulated postscript (eps) ouput. It is an alternative to the postscript terminal driver for those who would like to have their eps files look equal to e.g. screen output by the wxt terminal.

The cairolatex terminal uses the cairo backend of the pdfcairo or epscairo terminal to produce graphs for inclusion in LaTeX documents. It creates pdf or eps graphics but transfers texts to LaTeX in the same way as the epslatex terminal.

The windows terminal driver has been revised to suport transparency, antialiasing, buffered output, multiple graph windows and copying to clipboard and saving of graphs as emf files. It has many new options and a revised user interface. Additionaly, the code of the text console has been largely rewritten to support wrapping of long lines. Help is now provided via HTML.

Backwards compatibility

Gnuplot version 4.0 deprecated certain syntax used in earlier versions, but continued to recognize it. This is now under the control of a configuration option, and can be enabled as follows:

     ./configure --enable-backwards-compatibility

Notice: Deprecated syntax items may be removed entirely in some future version of gnuplot.

One major difference is the introduction of keywords to disambiguate complex commands, particularly commands containing string variables. A notable issue was the use of bare numbers to specify offsets, line and point types. Illustrative examples:

Deprecated:

     set title "Old" 0,-1
     set data linespoints
     plot 1 2 4               # horizontal line at y=1

New:

     TITLE = "New"
     set title TITLE offset char 0, char -1
     set style data linespoints
     plot 1 linetype 2 pointtype 4

Batch/Interactive Operation

Gnuplot may be executed in either batch or interactive modes, and the two may even be mixed together on many systems.

Any command-line arguments are assumed to be either program options (first character is -) or names of files containing gnuplot commands. The option -e "command" may be used to force execution of a gnuplot command. Each file or command string will be executed in the order specified. The special filename "-" is indicates that commands are to be read from stdin. Gnuplot exits after the last file is processed. If no load files and no command strings are specified, gnuplot accepts interactive input from stdin.

Both the exit and quit commands terminate the current command file and load the next one, until all have been processed.

Examples:

To launch an interactive session:

     gnuplot

To launch a batch session using two command files "input1" and "input2":

     gnuplot input1 input2

To launch an interactive session after an initialization file "header" and followed by another command file "trailer":

     gnuplot header - trailer

To give gnuplot commands directly in the command line, using the "-persist" option so that the plot remains on the screen afterwards:

     gnuplot -persist -e "set title 'Sine curve'; plot sin(x)"

To set user-defined variables a and s prior to executing commands from a file:

     gnuplot -e "a=2; s='file.png'" input.gpl

Canvas size

In earlier versions of gnuplot, some terminal types used the values from set size to control also the size of the output canvas; others did not. The use of 'set size' for this purpose was deprecated in version 4.2. Since version 4.4 almost all terminals now behave as follows:

set term <terminal_type> size <XX>, <YY> controls the size of the output file, or "canvas". Please see individual terminal documentation for allowed values of the size parameters. By default, the plot will fill this canvas.

set size <XX>, <YY> scales the plot itself relative to the size of the canvas. Scale values less than 1 will cause the plot to not fill the entire canvas. Scale values larger than 1 will cause only a portion of the plot to fit on the canvas. Please be aware that setting scale values larger than 1 may cause problems on some terminal types.

The major exception to this convention is the PostScript driver, which by default continues to act as it has in earlier versions. Be warned that the next version of gnuplot may change the default behaviour of the PostScript driver as well.

Example:

     set size 0.5, 0.5
     set term png size 600, 400
     set output "figure.png"
     plot "data" with lines

These commands will produce an output file "figure.png" that is 600 pixels wide and 400 pixels tall. The plot will fill the lower left quarter of this canvas. This is consistent with the way multiplot mode has always worked.

Command-line-editing

Command-line editing and command history are supported using either an external gnu readline library, an external BSD libedit library, or a built-in equivalent. This choice is a configuration option at the time gnuplot is built.

The editing commands of the built-in version are given below. Please note that the action of the DEL key is system-dependent. The gnu readline and BSD libedit libraries have their own documentation.



Command-line Editing Commands




CharacterFunction


Line Editing

^B move back a single character.
^F move forward a single character.
^A move to the beginning of the line.
^E move to the end of the line.
^H delete the previous character.
DEL delete the current character.
^D delete current character. EOF if line is empty.
^K delete from current position to the end of line.
^L, ^R redraw line in case it gets trashed.
^U delete the entire line.
^W delete previous word.


History

^P move back through history.
^N move forward through history.


Comments

Comments are supported as follows: a # may appear in most places in a line and gnuplot will ignore the rest of the line. It will not have this effect inside quotes, inside numbers (including complex numbers), inside command substitutions, etc. In short, it works anywhere it makes sense to work.

See also set datafile commentschars (p. 145) for specifying comment characters in data files. Note that if a comment line ends in '\' then the subsequent line is also treated as a comment.

Coordinates

The commands set arrow, set key, set label and set object allow you to draw something at an arbitrary position on the graph. This position is specified by the syntax:

     {<system>} <x>, {<system>} <y> {,{<system>} <z>}

Each <system> can either be first, second, graph, screen, or character.

first places the x, y, or z coordinate in the system defined by the left and bottom axes; second places it in the system defined by the second axes (top and right); graph specifies the area within the axes — 0,0 is bottom left and 1,1 is top right (for splot, 0,0,0 is bottom left of plotting area; use negative z to get to the base — see set xyplane (p. 224)); screen specifies the screen area (the entire area — not just the portion selected by set size), with 0,0 at bottom left and 1,1 at top right; and character gives the position in character widths and heights from the bottom left of the screen area (screen 0,0), character coordinates depend on the chosen font size.

If the coordinate system for x is not specified, first is used. If the system for y is not specified, the one used for x is adopted.

In some cases, the given coordinate is not an absolute position but a relative value (e.g., the second position in set arrow ... rto). In most cases, the given value serves as difference to the first position. If the given coordinate resides in a logarithmic axis the value is interpreted as factor. For example,

     set logscale x
     set arrow 100,5 rto 10,2

plots an arrow from position 100,5 to position 1000,7 since the x axis is logarithmic while the y axis is linear.

If one (or more) axis is timeseries, the appropriate coordinate should be given as a quoted time string according to the timefmt format string. See set xdata (p. 216) and set timefmt (p. 211). Gnuplot will also accept an integer expression, which will be interpreted as seconds from 1 January 2000.

Datastrings

Data files may contain string data consisting of either an arbitrary string of printable characters containing no whitespace or an arbitrary string of characters, possibly including whitespace, delimited by double quotes. The following sample line from a datafile is interpreted to contain four columns, with a text field in column 3:

 1.000 2.000 "Third column is all of this text" 4.00

Text fields can be positioned within a 2-D or 3-D plot using the commands:

 plot 'datafile' using 1:2:4 with labels
 splot 'datafile using 1:2:3:4 with labels

A column of text data can also be used to label the ticmarks along one or more of the plot axes. The example below plots a line through a series of points with (X,Y) coordinates taken from columns 3 and 4 of the input datafile. However, rather than generating regularly spaced tics along the x axis labeled numerically, gnuplot will position a tic mark along the x axis at the X coordinate of each point and label the tic mark with text taken from column 1 of the input datafile.

 set xtics
 plot 'datafile' using 3:4:xticlabels(1) with linespoints

There is also an option that will interpret the first entry in a column of input data (i.e. the column heading) as a text field, and use it as the key title for data plotted from that column. The example given below will use the first entry in column 2 to generate a title in the key box, while processing the remainder of columns 2 and 4 to draw the required line:

 plot 'datafile' using 1:(f($2)/$4) with lines title columnhead(2)

Another example:

 plot for [i=2:6] 'datafile' using i title "Results for ".columnhead(i)

See set style labels (p. 69), using xticlabels (p. 112), plot title (p. 119), using (p. 109).

Enhanced text mode

Many terminal types support an enhanced text mode in which additional formatting information is embedded in the text string. For example, "x^2" will write x-squared as we are used to seeing it, with a superscript 2. This mode is normally selected when you set the terminal, e.g. "set term png enhanced", but may also be toggled afterward using "set termoption enhanced", or by marking individual strings as in "set label 'x_2' noenhanced".





Enhanced Text Control Codes








Control Example Result Explanation




^ a^x ax superscript
_ a_x ax subscript
@ a@^b_{cd} acdb phantom box (occupies no width)
& d&{space}bd␣␣␣␣␣binserts space of specified length
~ ~a{.8-} ã overprints '-' on 'a', raised by .8
        times the current fontsize




Braces can be used to place multiple-character text where a single character is expected (e.g., 2^{10}). To change the font and/or size, use the full form: {/[fontname][=fontsize | *fontscale] text}. Thus {/Symbol=20 G} is a 20 pt GAMMA and {/*0.75 K} is a K at three-quarters of whatever fontsize is currently in effect. (The '/' character MUST be the first character after the '{'.)

The phantom box is useful for a@^b_c to align superscripts and subscripts but does not work well for overwriting an accent on a letter. For the latter, it is much better to use an encoding (e.g. iso_8859_1 or utf8) that contains a large variety of letters with accents or other diacritical marks. See set encoding (p. 150). Since the box is non-spacing, it is sensible to put the shorter of the subscript or superscript in the box (that is, after the @).

Space equal in length to a string can be inserted using the '&' character. Thus

       'abc&{def}ghi'

would produce

       'abc   ghi'.

The '~' character causes the next character or bracketed text to be overprinted by the following character or bracketed text. The second text will be horizontally centered on the first. Thus '~a/' will result in an 'a' with a slash through it. You can also shift the second text vertically by preceding the second text with a number, which will define the fraction of the current fontsize by which the text will be raised or lowered. In this case the number and text must be enclosed in brackets because more than one character is necessary. If the overprinted text begins with a number, put a space between the vertical offset and the text ('~{abc}{.5 000}'); otherwise no space is needed ('~{abc}{.5 — }'). You can change the font for one or both strings ('~ a{.5 /*.2 o}' — an 'a' with a one-fifth-size 'o' on top — and the space between the number and the slash is necessary), but you can't change it after the beginning of the string. Neither can you use any other special syntax within either string. You can, of course, use control characters by escaping them (see below), such as '~a{\^}'

You can access special symbols numerically by specifying \character-code (in octal), e.g., {/Symbol \245} is the symbol for infinity. This does not work for multibyte encodings like UTF-8, however. In a UTF-8 environment, you should be able to enter multibyte sequences implicitly by typing or otherwise selecting the character you want.

You can escape control characters using \, e.g., \\, \{, and so on.

But be aware that strings in double-quotes are parsed differently than those enclosed in single-quotes. The major difference is that backslashes may need to be doubled when in double-quoted strings.

Examples (these are hard to describe in words — try them!):

     set xlabel 'Time (10^6 {/Symbol m}s)'
     set title '{/Symbol=18 \\362@_{/=9.6 0}^{/=12 x}} \\
                {/Helvetica e^{-{/Symbol m}^2/2} d}{/Symbol m}'

The file "ps_guide.ps" in the /docs/psdoc subdirectory of the gnuplot source distribution contains more examples of the enhanced syntax.

Environment

A number of shell environment variables are understood by gnuplot. None of these are required, but may be useful.

If GNUTERM is defined, it is used as the name of the terminal type to be used. This overrides any terminal type sensed by gnuplot on start-up, but is itself overridden by the .gnuplot (or equivalent) start-up file (see startup (p. 47)) and, of course, by later explicit changes.

GNUHELP may be defined to be the pathname of the HELP file (gnuplot.gih).

On VMS, the logical name GNUPLOT$HELP should be defined as the name of the help library for gnuplot. The gnuplot help can be put inside any system help library, allowing access to help from both within and outside gnuplot if desired.

On Unix, HOME is used as the name of a directory to search for a .gnuplot file if none is found in the current directory. On MS-DOS, Windows and OS/2, GNUPLOT is used. On Windows, the NT-specific variable USERPROFILE is also tried. VMS, SYS$LOGIN: is used. Type help startup.

On Unix, PAGER is used as an output filter for help messages.

On Unix, SHELL is used for the shell command. On MS-DOS and OS/2, COMSPEC is used for the shell command.

FIT_SCRIPT may be used to specify a gnuplot command to be executed when a fit is interrupted — see fit (p. 79). FIT_LOG specifies the default filename of the logfile maintained by fit.

GNUPLOT_LIB may be used to define additional search directories for data and command files. The variable may contain a single directory name, or a list of directories separated by a platform-specific path separator, eg. ':' on Unix, or ';' on DOS/Windows/OS/2 platforms. The contents of GNUPLOT_LIB are appended to the loadpath variable, but not saved with the save and save set commands.

Several gnuplot terminal drivers access TrueType fonts via the gd library. For these drivers the font search path is controlled by the environmental variable GDFONTPATH. Furthermore, a default font for these drivers may be set via the environmental variable GNUPLOT_DEFAULT_GDFONT.

The postscript terminal uses its own font search path. It is controlled by the environmental variable GNUPLOT_FONTPATH. The format is the same as for GNUPLOT_LIB. The contents of GNUPLOT_FONTPATH are appended to the fontpath variable, but not saved with the save and save set commands.

GNUPLOT_PS_DIR is used by the postscript driver to search for external prologue files. Depending on the build process, gnuplot contains either a built-in copy of those files or a default hardcoded path. You can use this variable have the postscript terminal use custom prologue files rather than the default files. See postscript prologue (p. 294).

Expressions

In general, any mathematical expression accepted by C, FORTRAN, Pascal, or BASIC is valid. The precedence of these operators is determined by the specifications of the C programming language. White space (spaces and tabs) is ignored inside expressions.

Complex constants are expressed as {<real>,<imag>}, where <real> and <imag> must be numerical constants. For example, {3,2} represents 3 + 2i; {0,1} represents 'i' itself. The curly braces are explicitly required here.

Note that gnuplot uses both "real" and "integer" arithmetic, like FORTRAN and C. Integers are entered as "1", "-10", etc; reals as "1.0", "-10.0", "1e1", 3.5e-1, etc. The most important difference between the two forms is in division: division of integers truncates: 5/2 = 2; division of reals does not: 5.0/2.0 = 2.5. In mixed expressions, integers are "promoted" to reals before evaluation: 5/2e0 = 2.5. The result of division of a negative integer by a positive one may vary among compilers. Try a test like "print -5/2" to determine if your system chooses -2 or -3 as the answer.

The integer expression "1/0" may be used to generate an "undefined" flag, which causes a point to ignored. Or you can use the pre-defined variable NaN to achieve the same result. See using (p. 109) for an example.

The real and imaginary parts of complex expressions are always real, whatever the form in which they are entered: in {3,2} the "3" and "2" are reals, not integers.

Gnuplot can also perform simple operations on strings and string variables. For example, the expression ("A" . "B" eq "AB") evaluates as true, illustrating the string concatenation operator and the string equality operator.

A string which contains a numerical value is promoted to the corresponding integer or real value if used in a numerical expression. Thus ("3" + "4" == 7) and (6.78 == "6.78") both evaluate to true. An integer, but not a real or complex value, is promoted to a string if used in string concatenation. A typical case is the use of integers to construct file names or other strings; e.g. ("file" . 4 eq "file4") is true.

Substrings can be specified using a postfixed range descriptor [beg:end]. For example, "ABCDEF"[3:4] == "CD" and "ABCDEF"[4:*] == "DEF" The syntax "string"[beg:end] is exactly equivalent to calling the built-in string-valued function substr("string",beg,end), except that you cannot omit either beg or end from the function call.

Functions

The math functions in gnuplot are the same as the corresponding functions in the Unix math library, except that all functions accept integer, real, and complex arguments unless otherwise noted. Functions that accept or return angles (e.g. sin(x), cos(x), arg(z)) treat angle values as radians, but this may be changed to degrees using the command set angles.




Math library functions






FunctionArgumentsReturns



abs(x) any absolute value of x, |x|; same type
abs(x) complex length of x, ∘ -----------------
  real(x)2 + imag(x)2
acos(x) any cos1x (inverse cosine)
acosh(x) any cosh1x (inverse hyperbolic cosine) in radians
airy(x) any Airy function Ai(x)
arg(x) complex the phase of x
asin(x) any sin1x (inverse sin)
asinh(x) any sinh1x (inverse hyperbolic sin) in radians
atan(x) any tan1x (inverse tangent)
atan2(y,x) int or real tan1(y∕x) (inverse tangent)
atanh(x) any tanh1x (inverse hyperbolic tangent) in radians
EllipticK(k) real k (-1:1) K(k) complete elliptic integral of the first kind
EllipticE(k) real k [-1:1] E(k) complete elliptic integral of the second kind
EllipticPi(n,k)real n<1, real k (-1:1)Π(n,k) complete elliptic integral of the third kind
besj0(x) int or real j0 Bessel function of x, in radians
besj1(x) int or real j1 Bessel function of x, in radians
besy0(x) int or real y0 Bessel function of x, in radians
besy1(x) int or real y1 Bessel function of x, in radians
ceil(x) any x, smallest integer not less than x (real part)
cos(x) any cosx, cosine of x
cosh(x) any coshx, hyperbolic cosine of x in radians
erf(x) any erf(real(x)), error function of real(x)
erfc(x) any erfc(real(x)), 1.0 - error function of real(x)
exp(x) any ex, exponential function of x
expint(n,x) int n 0, real x 0En(x) = 1tnext dt, exponential integral of x
floor(x) any x, largest integer not greater than x (real part)
gamma(x) any gamma(real(x)), gamma function of real(x)
ibeta(p,q,x) any ibeta(real(p,q,x)), ibeta function of real(p,q,x)
inverf(x) any inverse error function of real(x)
igamma(a,x) any igamma(real(a,x)), igamma function of real(a,x)
imag(x) complex imaginary part of x as a real number
invnorm(x) any inverse normal distribution function of real(x)
int(x) real integer part of x, truncated toward zero
lambertw(x) real Lambert W function
lgamma(x) any lgamma(real(x)), lgamma function of real(x)
log(x) any log ex, natural logarithm (base e) of x
log10(x) any log 10x, logarithm (base 10) of x
norm(x) any normal distribution (Gaussian) function of real(x)
rand(x) int pseudo random number in the interval [0:1]
real(x) any real part of x
sgn(x) any1 if x > 0, -1 if x < 0, 0 if x = 0. imag(x) ignored
sin(x) anysinx, sine of x
sinh(x) anysinhx, hyperbolic sine of x in radians
sqrt(x) any√--
 x, square root of x
tan(x) anytanx, tangent of x
tanh(x) anytanhx, hyperbolic tangent of x in radians
voigt(x,y)realVoigt/Faddeeva function y
π --exp(t2)-
(x−t)2+y2dt









String functions






Function ArgumentsReturns



gprintf(”format”,x,...) any string result from applying gnuplot's format parser
sprintf(”format”,x,...) multiple string result from C-language sprintf
strlen(”string”) string int length of string in bytes
strstrt(”string”,”key”) strings int index of first character of substring ”key”
substr(”string”,beg,end) multiple string ”string”[beg:end]
strftime(”timeformat”,t) any string result from applying gnuplot's time parser
strptime(”timeformat”,s) string seconds since year 2000 as given in string s
system(”command”) string string containing output stream of shell command
word(”string”,n) string, int returns the nth word in ”string”
words(”string”) string returns the number of words in ”string”






other gnuplot functions






Function Arguments Returns



column(x) int or string column x during datafile manipulation.
columnhead(x) int string containing first entry of column x in datafile.
defined(X) variable name[DEPRECATED] returns 1 if X is defined, 0 otherwise.
exists(”X”) string returns 1 if a variable named X is defined, 0 otherwise.
stringcolumn(x) int or string content of column x as a string.
timecolumn(x) int timecolumn x during datafile manipulation.
tm_hour(x) int the hour
tm_mday(x) int the day of the month
tm_min(x) int the minute
tm_mon(x) int the month
tm_sec(x) int the second
tm_wday(x) int the day of the week
tm_yday(x) int the day of the year
tm_year(x) int the year
time(x) any the current system time
valid(x) int test validity of column(x) during datafile manip.
value(”name”) string returns the value of the named variable.



Elliptic integrals

The EllipticK(k) function returns the complete elliptic integral of the first kind, i.e. the definite integral between 0 and pi/2 of the function (1-(k*sin(p))**2)**(-0.5). The domain of k is -1 to 1 (exclusive).

The EllipticE(k) function returns the complete elliptic integral of the second kind, i.e. the definite integral between 0 and pi/2 of the function (1-(k*sin(p))**2)**0.5. The domain of k is -1 to 1 (inclusive).

The EllipticPi(n,k) function returns the complete elliptic integral of the third kind, i.e. the definite integral between 0 and pi/2 of the function (1-(k*sin(p))**2)**(-0.5)/(1-n*sin(p)**2). The parameter n must be less than 1, while k must lie between -1 and 1 (exclusive). Note that by definition EllipticPi(0,k) == EllipticK(k) for all possible values of k.

Random number generator

The function rand() produces a sequence of pseudo-random numbers between 0 and 1 using an algorithm from P. L'Ecuyer and S. Cote, "Implementing a random number package with splitting facilities", ACM Transactions on Mathematical Software, 17:98-111 (1991).

     rand(0)     returns a pseudo random number in the interval [0:1]
                 generated from the current value of two internal
                 32-bit seeds.
     rand(-1)    resets both seeds to a standard value.
     rand(x)     for integer 0 < x < 2^31-1 sets both internal seeds
                 to x.
     rand({x,y}) for integer 0 < x,y < 2^31-1 sets seed1 to x and
                 seed2 to y.
Value

B = value("A") is effectively the same as B = A, where A is the name of a user-defined variable. This is useful when the name of the variable is itself held in a string variable. See user-defined variables (p. 35). It also allows you to read the name of a variable from a data file. If the argument is a numerical expression, value() returns the value of that expression. If the argument is a string that does not correspond to a currently defined variable, value() returns NaN.

Operators

The operators in gnuplot are the same as the corresponding operators in the C programming language, except that all operators accept integer, real, and complex arguments, unless otherwise noted. The ** operator (exponentiation) is supported, as in FORTRAN.

Parentheses may be used to change order of evaluation.

Unary

The following is a list of all the unary operators and their usages:




Unary Operators






SymbolExampleExplanation



- -a unary minus
+ +a unary plus (no-operation)
~ ~a * one's complement
! !a * logical negation
! a! * factorial
$ $3 * call arg/column during ‘using‘ manipulation



(*) Starred explanations indicate that the operator requires an integer argument.

Operator precedence is the same as in Fortran and C. As in those languages, parentheses may be used to change the order of operation. Thus -2**2 = -4, but (-2)**2 = 4.

The factorial operator returns a real number to allow a greater range.

Binary

The following is a list of all the binary operators and their usages:




Binary Operators






SymbolExampleExplanation



** a**b exponentiation
* a*b multiplication
/ a/b division
% a%b * modulo
+ a+b addition
- a-b subtraction
== a==b equality
!= a!=b inequality
< a<b less than
<= a<=b less than or equal to
> a>b greater than
>= a>=b greater than or equal to
& a&b * bitwise AND
^ a^b * bitwise exclusive OR
| a|b * bitwise inclusive OR
&& a&&b * logical AND
|| a||b * logical OR
= a = b assignment
, (a,b) serial evaluation
. A.B string concatenation
eq A eq B string equality
ne A ne B string inequality



(*) Starred explanations indicate that the operator requires integer arguments. Capital letters A and B indicate that the operator requires string arguments.

Logical AND (&&) and OR (||) short-circuit the way they do in C. That is, the second && operand is not evaluated if the first is false; the second || operand is not evaluated if the first is true.

Serial evaluation occurs only in parentheses and is guaranteed to proceed in left to right order. The value of the rightmost subexpression is returned.

Ternary

There is a single ternary operator:




Ternary Operator






SymbolExampleExplanation



?: a?b:c ternary operation



The ternary operator behaves as it does in C. The first argument (a), which must be an integer, is evaluated. If it is true (non-zero), the second argument (b) is evaluated and returned; otherwise the third argument (c) is evaluated and returned.

The ternary operator is very useful both in constructing piecewise functions and in plotting points only when certain conditions are met.

Examples:

Plot a function that is to equal sin(x) for 0 <= x < 1, 1/x for 1 <= x < 2, and undefined elsewhere:

     f(x) = 0<=x && x<1 ? sin(x) : 1<=x && x<2 ? 1/x : 1/0
     plot f(x)
Note that gnuplot quietly ignores undefined values, so the final branch of the function (1/0) will produce no plottable points. Note also that f(x) will be plotted as a continuous function across the discontinuity if a line style is used. To plot it discontinuously, create separate functions for the two pieces. (Parametric functions are also useful for this purpose.)

For data in a file, plot the average of the data in columns 2 and 3 against the datum in column 1, but only if the datum in column 4 is non-negative:

     plot 'file' using 1:( $4<0 ? 1/0 : ($2+$3)/2 )

For an explanation of the using syntax, please see plot datafile using (p. 109).

Summation

A summation expression has the form

     sum [<var> = <start> : <end>] <expression>
<var> is treated as an integer variable that takes on successive integral values from <start> to <end>. For each of these, the current value of <expression> is added to a running total whose final value becomes the value of the summation expression. Examples:

     print sum [i=1:10] i
         55.
     # Equivalent to plot 'data' using 1:($2+$3+$4+$5+$6+...)
     plot 'data' using 1 : (sum [col=2:MAXCOL] column(col))
It is not necessary that <expression> contain the variable <var>. Although <start> and <end> can be specified as variables or expressions, their value cannot be changed dynamically as a side-effect of carrying out the summation. If <end> is less than <start> then the value of the summation is zero.

Gnuplot-defined variables

Gnuplot maintains a number of read-only variables that reflect the current internal state of the program and the most recent plot. These variables begin with the prefix "GPVAL_". Examples include GPVAL_TERM, GPVAL_X_MIN, GPVAL_X_MAX, GPVAL_Y_MIN. Type show variables all to display the complete list and current values. Values related to axes parameters (ranges, log base) are values used during the last plot, not those currently set.

Example: To calculate the fractional screen coordinates of the point [X,Y]

    GRAPH_X = (X - GPVAL_X_MIN) / (GPVAL_X_MAX - GPVAL_X_MIN)
    GRAPH_Y = (Y - GPVAL_Y_MIN) / (GPVAL_Y_MAX - GPVAL_Y_MIN)
    SCREEN_X = GPVAL_TERM_XMIN + GRAPH_X * (GPVAL_TERM_XMAX - GPVAL_TERM_XMIN)
    SCREEN_Y = GPVAL_TERM_YMIN + GRAPH_Y * (GPVAL_TERM_YMAX - GPVAL_TERM_YMIN)
    FRAC_X = SCREEN_X / GPVAL_TERM_XSIZE
    FRAC_Y = SCREEN_Y / GPVAL_TERM_YSIZE

The read-only variable GPVAL_ERRNO is set to a non-zero value if any gnuplot command terminates early due to an error. The most recent error message is stored in the string variable GPVAL_ERRMSG. Both GPVAL_ERRNO and GPVAL_ERRMSG can be cleared using the command reset errors.

Interactive terminals with mouse functionality maintain read-only variables with the prefix "MOUSE_". See mouse variables (p. 45) for details.

The fit mechanism uses several variables with names that begin "FIT_". It is safest to avoid using such names. "FIT_LIMIT", however, is one that you may wish to redefine. Under set fit errorvariables, the error for each fitted parameter will be stored in a variable named like the parameter, but with "_err" appended. See the documentation on fit (p. 79) for details.

See user-defined variables (p. 35), reset errors (p. 126), mouse variables (p. 45), and fit (p. 79).

User-defined variables and functions

New user-defined variables and functions of one through twelve variables may be declared and used anywhere, including on the plot command itself.

User-defined function syntax:

     <func-name>( <dummy1> {,<dummy2>} ... {,<dummy12>} ) = <expression>

where <expression> is defined in terms of <dummy1> through <dummy12>.

User-defined variable syntax:

     <variable-name> = <constant-expression>

Examples:

     w = 2
     q = floor(tan(pi/2 - 0.1))
     f(x) = sin(w*x)
     sinc(x) = sin(pi*x)/(pi*x)
     delta(t) = (t == 0)
     ramp(t) = (t > 0) ? t : 0
     min(a,b) = (a < b) ? a : b
     comb(n,k) = n!/(k!*(n-k)!)
     len3d(x,y,z) = sqrt(x*x+y*y+z*z)
     plot f(x) = sin(x*a), a = 0.2, f(x), a = 0.4, f(x)

     file = "mydata.inp"
     file(n) = sprintf("run_%d.dat",n)

The final two examples illustrate a user-defined string variable and a user-defined string function.

Note that the variables pi (3.14159...) and NaN (IEEE "Not a Number") are already defined. You can redefine these to something else if you really need to. The original values can be recovered by setting:

     NaN = GPVAL_NaN
     pi  = GPVAL_pi

Other variables may be defined under various gnuplot operations like mousing in interactive terminals or fitting; see gnuplot-defined variables (p. 35) for details.

You can check for existence of a given variable V by the exists("V") expression. For example

     a = 10
     if (exists("a")) print "a is defined"
     if (!exists("b")) print "b is not defined"

Valid names are the same as in most programming languages: they must begin with a letter, but subsequent characters may be letters, digits, or "_".

Each function definition is made available as a special string-valued variable with the prefix 'GPFUN_'.

Example:

     set label GPFUN_sinc at graph .05,.95

See show functions (p. 155), functions (p. 115), gnuplot-defined variables (p. 35), macros (p. 49), value (p. 32).

Fonts

Gnuplot does not provide any fonts of its own. It relies on external font handling, the details of which unfortunately vary from one terminal type to another. Brief documentation of font mechanisms that apply to more than one terminal type is given here. For information on font use by other individual terminals, see the documentation for that terminal.

Cairo (pdfcairo, pngcairo, epscairo, wxt terminals)

Sorry, this section is under construction. These terminals find and access fonts using the external fontconfig tool set. Please see the fontconfig user manual.

It is usually sufficient in gnuplot to request a font by a generic name and size, letting fontconfig substitute a similar font if necessary. The following will probably all work:

    set term pdfcairo font "sans,12"
    set term pdfcairo font "Times,12"
    set term pdfcairo font "Times-New-Roman,12"

Gd (png, gif, jpeg terminals)

Font handling for the png, gif, and jpeg terminals is done by the external library libgd. Five basic fonts are provided directly by libgd. These are tiny (5x8 pixels), small (6x12 pixels), medium, (7x13 Bold), large (8x16) or giant (9x15 pixels). These fonts cannot be scaled or rotated. Use one of these keywords instead of the font keyword. E.g.

    set term png tiny

On most systems libgd also provides access to Adobe Type 1 fonts (*.pfa) and TrueType fonts (*.ttf). You must give the name of the font file, not the name of the font inside it, in the form "<face> {,<pointsize>}". <face> is either the full pathname to the font file, or the first part of a filename in one of the directories listed in the GDFONTPATH environmental variable. That is, 'set term png font "Face"' will look for a font file named either <somedirectory>/Face.ttf or <somedirectory>/Face.pfa. For example, if GDFONTPATH contains /usr/local/fonts/ttf:/usr/local/fonts/pfa then the following pairs of commands are equivalent

    set term png font "arial"
    set term png font "/usr/local/fonts/ttf/arial.ttf"
    set term png font "Helvetica"
    set term png font "/usr/local/fonts/pfa/Helvetica.pfa"

To request a default font size at the same time:

    set term png font "arial,11"

Both TrueType and Adobe Type 1 fonts are fully scalable and rotatable. If no specific font is requested in the "set term" command, gnuplot checks the environmental variable GNUPLOT_DEFAULT_GDFONT to see if there is a preferred default font.

Postscript (also encapsulated postscript *.eps)

PostScript font handling is done by the printer or viewing program. Gnuplot can create valid PostScript or encapsulated PostScript (*.eps) even if no fonts at all are installed on your computer. Gnuplot simply refers to the font by name in the output file, and assumes that the printer or viewing program will know how to find or approximate a font by that name.

All PostScript printers or viewers should know about the standard set of Adobe fonts Times-Roman, Helvetica, Courier, and Symbol. It is likely that many additional fonts are also available, but the specific set depends on your system or printer configuration. Gnuplot does not know or care about this; the output *.ps or *.eps files that it creates will simply refer to whatever font names you request.

Thus

    set term postscript eps font "Times-Roman,12"
will produce output that is suitable for all printers and viewers.

On the other hand

    set term postscript eps font "Garamond-Premier-Pro-Italic"
will produce an output file that contains valid PostScript, but since it refers to a specialized font, only some printers or viewers will be able to display the specific font that was requested. Most will substitute a different font.

However, it is possible to embed a specific font in the output file so that all printers will be able to use it. This requires that the a suitable font description file is available on your system. Note that some font files require specific licensing if they are to be embedded in this way. See postscript fontfile (p. 292) for more detailed description and examples.

Glossary

Throughout this document an attempt has been made to maintain consistency of nomenclature. This cannot be wholly successful because as gnuplot has evolved over time, certain command and keyword names have been adopted that preclude such perfection. This section contains explanations of the way some of these terms are used.

A "page" or "screen" or "canvas" is the entire area addressable by gnuplot. On a desktop it is a full window; on a plotter, it is a single sheet of paper; in svga mode it is the full monitor screen.

A screen may contain one or more "plots". A plot is defined by an abscissa and an ordinate, although these need not actually appear on it, as well as the margins and any text written therein.

A plot contains one "graph". A graph is defined by an abscissa and an ordinate, although these need not actually appear on it.

A graph may contain one or more "lines". A line is a single function or data set. "Line" is also a plotting style. The word will also be used in sense "a line of text". Presumably the context will remove any ambiguity.

The lines on a graph may have individual names. These may be listed together with a sample of the plotting style used to represent them in the "key", sometimes also called the "legend".

The word "title" occurs with multiple meanings in gnuplot. In this document, it will always be preceded by the adjective "plot", "line", or "key" to differentiate among them. A 2D graph may have up to four labelled axes. The names of the four axes are "x" for the axis along the bottom border of the plot, "y" for the axis along the left border, "x2" for the top border, and "y2" for the right border. See axes (p. 93).

A 3D graph may have up to three labelled axes "x", "y" and "z". It is not possible to say where on the graph any particular axis will fall because you can change the direction from which the graph is seen with set view.

When discussing data files, the term "record" will be resurrected and used to denote a single line of text in the file, that is, the characters between newline or end-of-record characters. A "point" is the datum extracted from a single record. A "datablock" is a set of points from consecutive records, delimited by blank records. A line, when referred to in the context of a data file, is a subset of a datablock.

Linetypes, colors, and styles

Each gnuplot terminal type provides a set of distinct "linetypes". These may differ in color, in thickness, in dot/dash pattern, or in some combination of color and dot/dash. The default linetypes for a particular terminal can be previewed by issuing the test command after setting the terminal type. The pre-defined colors and dot/dash patterns are not guaranteed to be consistent for all terminal types, but all terminals use the special linetype -1 to mean a solid line in the primary foreground color (normally black). Most terminals also recognize the special linetype "bgnd" to mean a solid line in the background color.

You can redefine the default linetype properties either interactively or via an initialization file. This allows you to customize the colors and other properties of the lines used by all gnuplot plotting commands. See set linetype (p. 166).

By default, successive functions or datafiles plotted by a single command will be assigned successive linetypes. You can override this default sequence by specifying a particular linetype for any function, datafile, or plot element.

Examples:

    plot "foo", "bar"                 # plot two files using linetypes 1, 2
    plot sin(x) linetype 4            # terminal-specific linetype color 4
    plot sin(x) lt -1                 # black

For many terminal types it is also possible to assign user-defined colors using explicit rgb (red, green, blue) values, named colors, or color values that refer to the current pm3d palette.

Examples:

    plot sin(x) lt rgb "violet"       # one of gnuplot's named colors
    plot sin(x) lt rgb "#FF00FF"      # explicit RGB triple in hexadecimal
    plot sin(x) lt palette cb -45     # whatever color corresponds to -45
                                      # in the current cbrange of the palette
    plot sin(x) lt palette frac 0.3   # fractional value along the palette

See show colornames (p. 141), set palette (p. 187), cbrange (p. 230).

For terminals that support dot/dash patterns, each default linetype has both a dot-dash pattern and a default color. Gnuplot does not currently provide a mechanism for changing the dot-dash pattern, so if you want both a particular dash pattern and a particular color you must first choose a linetype that has the required dash pattern, then override the default color using the keyword linecolor, abbreviated lc. For example, the postscript terminal provides a dashed blue line as linetype 3. The plot commands below use this same dash pattern for three plots, one in blue (the default), another in red (the default for linetype 1), and a third in gold.

Example:

    set term postscript dashed color
    plot 'foo' lt 3, 'baz' lt 3 linecolor 1, 'bar' lt 3 lc rgb 'gold'

Colorspec

Many commands allow you to specify a linetype with an explicit color. Terminal-independent color choice is only possible for terminals that support RGB color or pm3d palettes.

Syntax:

     ... {linecolor | lc} {<colorspec> | <n>}
     ... {textcolor | tc} {<colorspec> | {linetype | lt} <n>}

where <colorspec> has one of the following forms:

     rgbcolor "colorname"
     rgbcolor "#RRGGBB"
     rgbcolor variable       # color is read from input file
     palette frac <val>      # <val> runs from 0 to 1
     palette cb <value>      # <val> lies within cbrange
     palette z
     variable                # color index is read from input file

The "<n>" is the linetype number the color of which is used, see test (p. 238).

"colorname" refers to one of the color names built in to gnuplot. For a list of the available names, see show colornames (p. 141).

"#RRGGBB" is a hexadecimal constant preceded by the "#" symbol. The RRGGBB represents the red, green, and blue components of the color, each on a scale from 0 - 255. For example, magenta = full-scale red + full-scale blue would be represented by #FF00FF, which is the hexadecimal representation of (255 << 16) + (0 << 8) + (255).

The color palette is a linear gradient of colors that smoothly maps a single numerical value onto a particular color. Two such mappings are always in effect. palette frac maps a fractional value between 0 and 1 onto the full range of the color palette. palette cb maps the range of the color axis onto the same palette. See set cbrange (p. 230). See also set colorbox (p. 140). You can use either of these to select a constant color from the current palette.

"palette z" maps the z value of each plot segment or plot element into the cbrange mapping of the palette. This allows smoothly-varying color along a 3d line or surface. It also allows coloring 2D plots by palette values read from an extra column of data (not all 2D plot styles allow an extra column).

Background color

Most terminals now allow you to set an explicit background color for the plot. The special linetype bgnd will draw in this color, and bgnd is also recognized as a color. Examples:

                                                                                         
                                                                                         
    # This will erase a section of the canvas by writing over it in the
    # background color
    set term wxt background rgb "gray75"
    set object 1 rectangle from x0,y0 to x1,y1 fillstyle solid fillcolor bgnd
    # This will draw an "invisible" line along the x axis
    plot 0 lt bgnd
Linecolor variable

lc variable tells the program to use the value read from one column of the input data as a linetype index, and use the color belonging to that linetype. This requires a corresponding additional column in the using specifier. Text colors can be set similarly using tc variable.

Examples:

     # Use the third column of data to assign colors to individual points
     plot 'data' using 1:2:3 with points lc variable

     # A single data file may contain multiple sets of data, separated by two
     # blank lines.  Each data set is assigned as index value (see ‘index‘)
     # that can be retrieved via the ‘using‘ specifier ‘column(-2)‘.
     # See ‘pseudocolumns‘.  This example uses to value in column -2 to
     # draw each data set in a different line color.
     plot 'data' using 1:2:(column(-2)) with lines lc variable

Rgbcolor variable

You can assign a separate color for each data point, line segment, or label in your plot. lc rgbcolor variable tells the program to read RGB color information for each line in the data file. This requires a corresponding additional column in the using specifier. The extra column is interpreted as a 24-bit packed RGB triple. If the value is provided directly in the data file it is easiest to give it as a hexidecimal value (see rgbcolor (p. 40)). Alternatively, the using specifier can contain an expression that evaluates to a 24-bit RGB color as in the example below. Text colors are similarly set using tc rgbcolor variable.

Example:

     # Place colored points in 3D at the x,y,z coordinates corresponding to
     # their red, green, and blue components
     rgb(r,g,b) = 65536 * int(r) + 256 * int(g) + int(b)
     splot "data" using 1:2:3:(rgb($1,$2,$3)) with points lc rgb variable

Linestyles vs linetypes

Lines can have additional properties such as linewidth. You can associate these various properties, as well as equivalent properties for point symbols, into user-defined "linestyles" using the command set style line. Once you have defined a linestyle, you can use it in a plot command to control the appearance of one or more plot elements.

Whereas linetypes are permanent (they last until you explicitly redefine them), linestyles are temporary. They only last until the next reset of the graphics state.

Examples:

    # define a new line style with terminal-independent color cyan,
    # linewidth 3, and associated point type 6 (a circle with a dot in it).
    set style line 5 lt rgb "cyan" lw 3 pt 6
    plot sin(x) with linespoints ls 5          # user-defined line style 5

Mouse input

Many terminals allow interaction with the current plot using the mouse. Some also support the definition of hotkeys to activate pre-defined functions by hitting a single key while the mouse focus is in the active plot window. It is even possible to combine mouse input with batch command scripts, by invoking the command pause mouse and then using the mouse variables returned by mouse clicking as parameters for subsequent scripted actions. See bind (p. 43) and mouse variables (p. 45). See also the command set mouse (p. 171).

Bind

Syntax:

     bind {allwindows} [<key-sequence>] ["<gnuplot commands>"]
     bind <key-sequence> ""
     reset bind

The bind allows defining or redefining a hotkey, i.e. a sequence of gnuplot commands which will be executed when a certain key or key sequence is pressed while the driver's window has the input focus. Note that bind is only available if gnuplot was compiled with mouse support and it is used by all mouse-capable terminals. A user-specified binding supersedes any builtin bindings, except that <space> and 'q' cannot normally be rebound. For an exception, see bind space (p. 45).

Mouse buttons cannot be rebound.

You get the list of all hotkeys by typing show bind or bind or by typing the hotkey 'h' in the graph window.

Key bindings are restored to their default state by reset bind.

Note that multikey-bindings with modifiers must be given in quotes.

Normally hotkeys are only recognized when the currently active plot window has focus. bind allwindows <key> ... (short form: bind all <key> ...) causes the binding for <key> to apply to all gnuplot plot windows, active or not. In this case gnuplot variable MOUSE_KEY_WINDOW is set to the ID of the originating window, and may be used by the bound command.

Examples:

- set bindings:

   bind a "replot"
   bind "ctrl-a" "plot x*x"
   bind "ctrl-alt-a" 'print "great"'
   bind Home "set view 60,30; replot"
   bind all Home 'print "This is window ",MOUSE_KEY_WINDOW'

- show bindings:

   bind "ctrl-a"          # shows the binding for ctrl-a
   bind                   # shows all bindings
   show bind              # show all bindings

- remove bindings:

   bind "ctrl-alt-a" ""   # removes binding for ctrl-alt-a
                          # (note that builtins cannot be removed)
   reset bind             # installs default (builtin) bindings
   bind!                  # deprecated form of "reset bind"

- bind a key to toggle something:

 v=0
 bind "ctrl-r" "v=v+1;if(v%2)set term x11 noraise; else set term x11 raise"

Modifiers (ctrl / alt) are case insensitive, keys not:

   ctrl-alt-a == CtRl-alT-a
   ctrl-alt-a != ctrl-alt-A

List of modifiers (alt == meta):

   ctrl, alt

List of supported special keys:

  "BackSpace", "Tab", "Linefeed", "Clear", "Return", "Pause", "Scroll_Lock",
  "Sys_Req", "Escape", "Delete", "Home", "Left", "Up", "Right", "Down",
  "PageUp", "PageDown", "End", "Begin",
  "KP_Space", "KP_Tab", "KP_Enter", "KP_F1", "KP_F2", "KP_F3", "KP_F4",
  "KP_Home", "KP_Left", "KP_Up", "KP_Right", "KP_Down", "KP_PageUp",
  "KP_PageDown", "KP_End", "KP_Begin", "KP_Insert", "KP_Delete", "KP_Equal",
  "KP_Multiply", "KP_Add", "KP_Separator", "KP_Subtract", "KP_Decimal",
  "KP_Divide",
  "KP_1" - "KP_9", "F1" - "F12"

The following are window events rather than actual keys

  "Close"

See also help for mouse (p. 171).

Bind space

If gnuplot was built with configuration option –enable-raise-console, then typing <space> in the plot window raises gnuplot's command window. This hotkey can be changed to ctrl-space by starting gnuplot as 'gnuplot -ctrlq', or by setting the XResource 'gnuplot*ctrlq'. See x11 command-line-options (p. 313).

Mouse variables

When mousing is active, clicking in the active window will set several user variables that can be accessed from the gnuplot command line. The coordinates of the mouse at the time of the click are stored in MOUSE_X MOUSE_Y MOUSE_X2 and MOUSE_Y2. The mouse button clicked, and any meta-keys active at that time, are stored in MOUSE_BUTTON MOUSE_SHIFT MOUSE_ALT and MOUSE_CTRL. These variables are set to undefined at the start of every plot, and only become defined in the event of a mouse click in the active plot window. To determine from a script if the mouse has been clicked in the active plot window, it is sufficient to test for any one of these variables being defined.

     plot 'something'
     pause mouse
     if (defined(MOUSE_BUTTON)) call 'something_else'; \
     else print "No mouse click."

It is also possible to track keystrokes in the plot window using the mousing code.

     plot 'something'
     pause mouse keypress
     print "Keystroke ", MOUSE_KEY, " at ", MOUSE_X, " ", MOUSE_Y

When pause mouse keypress is terminated by a keypress, then MOUSE_KEY will contain the ascii character value of the key that was pressed. MOUSE_CHAR will contain the character itself as a string variable. If the pause command is terminated abnormally (e.g. by ctrl-C or by externally closing the plot window) then MOUSE_KEY will equal -1.

Note that after a zoom by mouse, you can read the new ranges as GPVAL_X_MIN, GPVAL_X_MAX, GPVAL_Y_MIN, and GPVAL_Y_MAX, see gnuplot-defined variables (p. 35).

Plotting

There are three gnuplot commands which actually create a plot: plot, splot and replot. plot generates 2D plots, splot generates 3D plots (actually 2D projections, of course), and replot appends its arguments to the previous plot or splot and executes the modified command.

Much of the general information about plotting can be found in the discussion of plot; information specific to 3D can be found in the splot section.

plot operates in either rectangular or polar coordinates – see set polar (p. 194) for details of the latter. splot operates only in rectangular coordinates, but the set mapping command allows for a few other coordinate systems to be treated. In addition, the using option allows both plot and splot to treat almost any coordinate system you'd care to define.

plot also lets you use each of the four borders – x (bottom), x2 (top), y (left) and y2 (right) – as an independent axis. The axes option lets you choose which pair of axes a given function or data set is plotted against. A full complement of set commands exists to give you complete control over the scales and labelling of each axis. Some commands have the name of an axis built into their names, such as set xlabel. Other commands have one or more axis names as options, such as set logscale xy. Commands and options controlling the z axis have no effect on 2D graphs.

splot can plot surfaces and contours in addition to points and/or lines. See set isosamples (p. 158) for information about defining the grid for a 3D function. See splot datafile (p. 231) for information about the requisite file structure for 3D data values, set contour (p. 141) and set cntrparam (p. 138) for information about contours.

In splot, control over the scales and labels of the axes are the same as with plot, except that commands and options controlling the x2 and y2 axes have no effect whereas of course those controlling the z axis do take effect.

Start-up (initialization)

When gnuplot is run, it first looks for a system-wide initialization file named gnuplotrc. The location of this file is determined when the program is built and is reported by show loadpath. The program then looks in the user's HOME directory for a file called .gnuplot on Unix-like systems or GNUPLOT.INI on other systems. (Windows and OS/2 will look for it in the directory named in the environment variable GNUPLOT; Windows will use USERPROFILE if GNUPLOT is not defined). Note: The program can be configured to look first in the current directory, but this is not recommended because it is bad security practice.

String constants and string variables

In addition to string constants, most gnuplot commands also accept a string variable, a string expression, or a function that returns a string. For example, the following four methods of creating a plot all result in the same plot title:

     four = "4"
     graph4 = "Title for plot #4"
     graph(n) = sprintf("Title for plot #%d",n)

     plot 'data.4' title "Title for plot #4"
     plot 'data.4' title graph4
     plot 'data.4' title "Title for plot #".four
     plot 'data.4' title graph(4)

Since integers are promoted to strings when operated on by the string concatenation operator, the following method also works:

     N = 4
     plot 'data.'.N title "Title for plot #".N

In general, elements on the command line will only be evaluated as possible string variables if they are not otherwise recognizable as part of the normal gnuplot syntax. So the following sequence of commands is legal, although probably should be avoided so as not to cause confusion:

     plot = "my_datafile.dat"
     title = "My Title"
     plot plot title title

There are three binary operators that require string operands: the string concatenation operator ".", the string equality operator "eq" and the string inequality operator "ne". The following example will print TRUE.

    if ("A"."B" eq "AB") print "TRUE"

See also the two string formatting functions gprintf (p. 152) and sprintf (p. 30).

Substrings can be specified by appending a range specifier to any string, string variable, or string-valued function. The range specifier has the form [begin:end], where begin is the index of the first character of the substring and end is the index of the last character of the substring. The first character has index 1. The begin or end fields may be empty, or contain '*', to indicate the true start or end of the original string. E.g. str[:] and str[*:*] both describe the full string str.

Substitution and Command line macros

When a command line to gnuplot is first read, i.e. before it is interpreted or executed, two forms of lexical substitution are performed. These are triggered by the presence of text in backquotes (ascii character 96) or preceded by @ (ascii character 64).

Substitution of system commands in backquotes

Command-line substitution is specified by a system command enclosed in backquotes. This command is spawned and the output it produces replaces the backquoted text on the command line. Some implementations also support pipes; see plot datafile special-filenames (p. 106).

Command-line substitution can be used anywhere on the gnuplot command line, except inside strings delimited by single quotes.

Example:

This will run the program leastsq and replace leastsq (including backquotes) on the command line with its output:

     f(x) = ‘leastsq

or, in VMS

     f(x) = ‘run leastsq

These will generate labels with the current time and userid:

     set label "generated on ‘date +%Y-%m-%d‘ by ‘whoami‘" at 1,1
     set timestamp "generated on %Y-%m-%d by ‘whoami‘"

Substitution of string variables as macros

Substitution of command line macros is disabled by default, but may be enabled using the set macros command. If macro substitution is enabled, the character @ is used to trigger substitution of the current value of a string variable into the command line. The text in the string variable may contain any number of lexical elements. This allows string variables to be used as command line macros. Only string constants may be expanded using this mechanism, not string-valued expressions. For example:

     set macros
     style1 = "lines lt 4 lw 2"
     style2 = "points lt 3 pt 5 ps 2"
     range1 = "using 1:3"
     range2 = "using 1:5"
     plot "foo" @range1 with @style1, "bar" @range2 with @style2

The line containing @ symbols is expanded on input, so that by the time it is executed the effect is identical to having typed in full

     plot "foo" using 1:3 with lines lt 4 lw 2, \
          "bar" using 1:5 with points lt 3 pt 5 ps 2

The function exists() may be useful in connection with macro evaluation. The following example checks that C can safely be expanded as the name of a user-defined variable:

     C = "pi"
     if (exists(C)) print C," = ", @C

Macro expansion does not occur inside either single or double quotes. However macro expansion does occur inside backquotes.

Macro expansion is handled as the very first thing the interpreter does when looking at a new line of commands and is only done once. Therefore, code like the following will execute correctly:

    A = "c=1"
    @A

but this line will not, since the macro is defined on the same line and will not be expanded in time

    A = "c=1"; @A   # will not expand to c=1

For execution of complete commands the evaluate command may also be handy.

String variables, macros, and command line substitution

The interaction of string variables, backquotes and macro substitution is somewhat complicated. Backquotes do not block macro substitution, so

     filename = "mydata.inp"
     lines = ‘ wc --lines @filename | sed "s/ .*//" 

results in the number of lines in mydata.inp being stored in the integer variable lines. And double quotes do not block backquote substitution, so

     mycomputer = "‘uname -n‘"

results in the string returned by the system command uname -n being stored in the string variable mycomputer.

However, macro substitution is not performed inside double quotes, so you cannot define a system command as a macro and then use both macro and backquote substitution at the same time.

      machine_id = "uname -n"
      mycomputer = "‘@machine_id‘"  # doesn't work!!

This fails because the double quotes prevent @machine_id from being interpreted as a macro. To store a system command as a macro and execute it later you must instead include the backquotes as part of the macro itself. This is accomplished by defining the macro as shown below. Notice that the sprintf format nests all three types of quotes.

     machine_id = sprintf('"‘uname -n‘"')
     mycomputer = @machine_id

Syntax

Options and any accompanying parameters are separated by spaces whereas lists and coordinates are separated by commas. Ranges are separated by colons and enclosed in brackets [], text and file names are enclosed in quotes, and a few miscellaneous things are enclosed in parentheses.

Commas are used to separate coordinates on the set commands arrow, key, and label; the list of variables being fitted (the list after the via keyword on the fit command); lists of discrete contours or the loop parameters which specify them on the set cntrparam command; the arguments of the set commands dgrid3d, dummy, isosamples, offsets, origin, samples, size, time, and view; lists of tics or the loop parameters which specify them; the offsets for titles and axis labels; parametric functions to be used to calculate the x, y, and z coordinates on the plot, replot and splot commands; and the complete sets of keywords specifying individual plots (data sets or functions) on the plot, replot and splot commands.

Parentheses are used to delimit sets of explicit tics (as opposed to loop parameters) and to indicate computations in the using filter of the fit, plot, replot and splot commands.

(Parentheses and commas are also used as usual in function notation.)

Square brackets are used to delimit ranges given in set, plot or splot commands.

Colons are used to separate extrema in range specifications (whether they are given on set, plot or splot commands) and to separate entries in the using filter of the plot, replot, splot and fit commands.

Semicolons are used to separate commands given on a single command line.

Curly braces are used in the syntax for enhanced text mode and to delimit blocks in if/then/else statements. They are also used to denote complex numbers: {3,2} = 3 + 2i.

The EEPIC, Imagen, Uniplex, LaTeX, and TPIC drivers allow a newline to be specified by \\ in a single-quoted string or \\\\ in a double-quoted string.

Quote Marks

Gnuplot uses three forms of quote marks for delimiting text strings, double-quote (ascii 34), single-quote (ascii 39), and backquote (ascii 96).

Filenames may be entered with either single- or double-quotes. In this manual the command examples generally single-quote filenames and double-quote other string tokens for clarity.

String constants and text strings used for labels, titles, or other plot elements may be enclosed in either single quotes or double quotes. Further processing of the quoted text depends on the choice of quote marks.

Backslash processing of special characters like \n (newline) and \345 (octal character code) is performed for double-quoted strings. In single-quoted strings, backslashes are just ordinary characters. To get a single-quote (ascii 39) in a single-quoted string, it has to be doubled. Thus the strings "d\" s' b\\" and 'd" s' ' b\' are completely equivalent.

Text justification is the same for each line of a multi-line string. Thus the center-justified string

     "This is the first line of text.\nThis is the second line."

will produce

                      This is the first line of text.
                         This is the second line.

but

     'This is the first line of text.\nThis is the second line.'

will produce

         This is the first line of text.\nThis is the second line.

Enhanced text processing is performed for both double-quoted text and single-quoted text, but only by terminals supporting this mode. See enhanced text (p. 26).

Back-quotes are used to enclose system commands for substitution into the command line. See substitution (p. 48).

Time/Date data

gnuplot supports the use of time and/or date information as input data. This feature is activated by the commands set xdata time, set ydata time, etc.

Internally all times and dates are converted to the number of seconds from the year 2000. The command set timefmt defines the format for all inputs: data files, ranges, tics, label positions — in short, anything that accepts a data value must receive it in this format. Since only one input format can be in force at a given time, all time/date quantities being input at the same time must be presented in the same format. Thus if both x and y data in a file are time/date, they must be in the same format.

The conversion to and from seconds assumes Universal Time (which is the same as Greenwich Standard Time). There is no provision for changing the time zone or for daylight savings. If all your data refer to the same time zone (and are all either daylight or standard) you don't need to worry about these things. But if the absolute time is crucial for your application, you'll need to convert to UT yourself.

Commands like show xrange will re-interpret the integer according to timefmt. If you change timefmt, and then show the quantity again, it will be displayed in the new timefmt. For that matter, if you give the deactivation command (like set xdata), the quantity will be shown in its numerical form.

The commands set format or set tics format define the format that will be used for tic labels, whether or not the specified axis is time/date.

If time/date information is to be plotted from a file, the using option must be used on the plot or splot command. These commands simply use white space to separate columns, but white space may be embedded within the time/date string. If you use tabs as a separator, some trial-and-error may be necessary to discover how your system treats them.

The time function can be used to get the current system time. This value can be converted to a date string with the strftime function, or it can be used in conjunction with timecolumn to generate relative time/date plots. The type of the argument determines what is returned. If the argument is an integer, time returns the current time as an integer, in seconds from 1 Jan 2000. If the argument is real (or complex), the result is real as well. The precision of the fractional (sub-second) part depends on your operating system. If the argument is a string, it is assumed to be a format string, and it is passed to strftime to provide a formatted time/date string.

The following example demonstrates time/date plotting.

Suppose the file "data" contains records like

     03/21/95 10:00  6.02e23

This file can be plotted by

     set xdata time
     set timefmt "%m/%d/%y"
     set xrange ["03/21/95":"03/22/95"]
     set format x "%m/%d"
     set timefmt "%m/%d/%y %H:%M"
     plot "data" using 1:3

which will produce xtic labels that look like "03/21".

See time_specifiers (p. 154).

Part II
Plotting styles

There are many plotting styles available in gnuplot. They are listed alphabetically below. The commands set style data and set style function change the default plotting style for subsequent plot and splot commands.

You also have the option to specify the plot style explicitly as part of the plot or splot command. If you want to mix plot styles within a single plot, you must specify the plot style for each component.

Example:

    plot 'data' with boxes, sin(x) with lines

Each plot style has its own expected set of data entries in a data file. For example by default the lines style expects either a single column of y values (with implicit x ordering) or a pair of columns with x in the first and y in the second. For more information on how to fine-tune how columns in a file are interpreted as plot data, see using (p. 109).

Boxerrorbars

The boxerrorbars style is only relevant to 2D data plotting. It is a combination of the boxes and yerrorbars styles. It uses 3, 4, or 5 columns of data:

Boxerrorbars

Fig. 2 Plot style boxerrorbars

    3 columns:  x  y  ydelta
    4 columns:  x  y  ydelta xdelta        # boxwidth != -2
    4 columns:  x  y  ylow  yhigh          # boxwidth == -2
    5 columns:  x  y  ylow  yhigh  xdelta

The boxwidth will come from the fourth column if the y errors are given as "ydelta" and the boxwidth was not previously set to -2.0 (set boxwidth -2.0) or from the fifth column if the y errors are in the form of "ylow yhigh". The special case boxwidth = -2.0 is for four-column data with y errors in the form "ylow yhigh". In this case the boxwidth will be calculated so that each box touches the adjacent boxes. The width will also be calculated in cases where three-column data are used.

An additional (4th, 5th or 6th) input column may be used to provide variable (per-datapoint) color information (see linecolor (p. 41) and rgbcolor variable (p. 42)). The error bar will be drawn in the same color as the border of the box.

The box height is determined from the y error in the same way as it is for the yerrorbars style — either from y-ydelta to y+ydelta or from ylow to yhigh, depending on how many data columns are provided. See also errorbar demo.

Boxes

The boxes style is only relevant to 2D plotting. It draws a box centered about the given x coordinate that extends from the x axis (not from the graph border) to the given y coordinate. It uses 2 or 3 columns of basic data. Additional input columns may be used to provide information such as variable line or fill color (see rgbcolor variable (p. 42)).

Boxes

Fig. 3 Plot style boxes

    2 columns:  x  y
    3 columns:  x  y  x_width

The width of the box is obtained in one of three ways. If the input data has a third column, this will be used to set the width of the box. If not, if a width has been set using the set boxwidth command, this will be used. If neither of these is available, the width of each box will be calculated automatically so that it touches the adjacent boxes.

The interior of the boxes is drawn according to the current fillstyle. See set style fill (p. 202) for details. Alternatively a new fillstyle may be specified in the plot command.

For fillstyle empty the box is not filled.

For fillstyle solid the box is filled with a solid rectangle of the current drawing color. There is an optional parameter <density> that controls the fill density; it runs from 0 (background color) to 1 (current drawing color).

For fillstyle pattern the box is filled in the current drawing color with a pattern, if supported by the terminal driver.

Examples:

To plot a data file with solid filled boxes with a small vertical space separating them (bargraph):

     set boxwidth 0.9 relative
     set style fill solid 1.0
     plot 'file.dat' with boxes

To plot a sine and a cosine curve in pattern-filled boxes style:

     set style fill pattern
     plot sin(x) with boxes, cos(x) with boxes

The sin plot will use pattern 0; the cos plot will use pattern 1. Any additional plots would cycle through the patterns supported by the terminal driver.

To specify explicit fillstyles for each dataset:

    plot 'file1' with boxes fs solid 0.25, \
         'file2' with boxes fs solid 0.50, \
         'file3' with boxes fs solid 0.75, \
         'file4' with boxes fill pattern 1, \
         'file5' with boxes fill empty

Boxplot

Boxplots are a common way to represent a statistical distribution of values. Quartile boundaries are determined such that 1/4 of the points have a value equal or less than the first quartile boundary, 1/2 of the points have a value equal or less than the second quartile (median) value, etc. A box is drawn around the region between the first and third quartiles, with a horizontal line at the median value. Whiskers extend from the box to user-specified limits. Points that lie outside these limits are drawn individually.

Boxplot

Fig. 4 Plot style boxplot

Examples

   # Place a boxplot at x coordinate 1.0 representing the y values in column 5
   plot 'data' using (1.0):5

   # Same plot but suppress outliers and force the width of the boxplot to 0.3
   set style boxplot nooutliers
   plot 'data' using (1.0):5:(0.3)

By default only one boxplot is produced that represents all y values from the second column of the using specification. However, an additional (fourth) colunm can be added to the specification. If present, the values of that column will be interpreted as the discrete levels of a factor variable. As many boxplots will be drawn as there are levels in the factor variable. The separation between these boxplots is 1.0 by default, but it can be changed by set style boxplot separation. By default, the value of the factor variable is shown as a tic label below (or above) each boxplot.

Example

   # Suppose that column 2 of 'data' contains either "control" or "treatment"
   # The following example produces two boxplots, one for each level of the
   # factor
   plot 'data' using (1.0):5:(0):2

The default width of the box can be set via set boxwidth <width> or may be specified as an optional 3rd column in the using clause of the plot command. The first and third columns (x coordinate and width) are normally provided as constants rather than as data columns.

By default the whiskers extend from the ends of the box to the most distant point whose y value lies within 1.5 times the interquartile range. By default outliers are drawn as circles (point type 7). The width of the bars at the end of the whiskers may be controlled using set bars.

These default properties may be changed using the set style boxplot command. See set style boxplot (p. 200), bars (p. 133), boxwidth (p. 136), fillstyle (p. 202), candlesticks (p. 57).

Boxxyerrorbars

The boxxyerrorbars style is only relevant to 2D data plotting. It is similar to the xyerrorbars style except that it draws rectangular areas rather than simple crosses. It uses either 4 or 6 basic columns of input data. Additional input columns may be used to provide information such as variable line or fill color (see rgbcolor variable (p. 42)).

Boxxyerrorbars

Fig. 5 Plot style boxxyerrorbars

    4 columns:  x  y  xdelta  ydelta
    6 columns:  x  y  xlow  xhigh  ylow  yhigh

The box width and height are determined from the x and y errors in the same way as they are for the xyerrorbars style — either from xlow to xhigh and from ylow to yhigh, or from x-xdelta to x+xdelta and from y-ydelta to y+ydelta, depending on how many data columns are provided.

An additional (5th or 7th) input column may be used to provide variable (per-datapoint) color information (see linecolor (p. 41) and rgbcolor variable (p. 42)).

The interior of the boxes is drawn according to the current fillstyle. See set style fill (p. 202) and boxes (p. 54) for details. Alternatively a new fillstyle may be specified in the plot command.

Candlesticks

The candlesticks style can be used for 2D data plotting of financial data or for generating box-and-whisker plots of statistical data. The symbol is a rectangular box, centered horizontally at the x coordinate and limited vertically by the opening and closing prices. A vertical line segment at the x coordinate extends up from the top of the rectangle to the high price and another down to the low. The vertical line will be unchanged if the low and high prices are interchanged.

Five columns of basic data are required:

Candlesticks

Fig. 6 Plot style candlestics

     financial data:   date  open  low  high  close
     whisker plot:     x  box_min  whisker_min  whisker_high  box_high

The width of the rectangle can be controlled by the set boxwidth command. For backwards compatibility with earlier gnuplot versions, when the boxwidth parameter has not been set then the width of the candlestick rectangle is controlled by set bars <width>.

Alternatively, an explicit width for each box-and-whiskers grouping may be specified in an optional 6th column of data. The width must be given in the same units as the x coordinate.

An additional (6th, or 7th if the 6th column is used for width data) input column may be used to provide variable (per-datapoint) color information (see linecolor (p. 41) and rgbcolor variable (p. 42)).

By default the vertical line segments have no crossbars at the top and bottom. If you want crossbars, which are typically used for box-and-whisker plots, then add the keyword whiskerbars to the plot command. By default these whiskerbars extend the full horizontal width of the candlestick, but you can modify this by specifying a fraction of the full width.

The usual convention for financial data is that the rectangle is empty if (open < close) and solid fill if (close < open). This is the behavior you will get if the current fillstyle is set to "empty". See fillstyle (p. 202). If you set the fillstyle to solid or pattern, then this will be used for all boxes independent of open and close values. See also set bars (p. 133) and financebars (p. 62). See also the candlestick and finance demos.

Note: To place additional symbols, such as the median value, on a box-and-whisker plot requires additional plot commands as in this example:

 # Data columns:X Min 1stQuartile Median 3rdQuartile Max
 set bars 4.0
 set style fill empty
 plot 'stat.dat' using 1:3:2:6:5 with candlesticks title 'Quartiles', \
      ''         using 1:4:4:4:4 with candlesticks lt -1 notitle

 # Plot with crossbars on the whiskers, crossbars are 50% of full width
 plot 'stat.dat' using 1:3:2:6:5 with candlesticks whiskerbars 0.5

See set boxwidth (p. 136), set bars (p. 133), set style fill (p. 202), and boxplot (p. 56).

Circles

The circles style plots a circle with an explicit radius at each data point. If three columns of data are present, they are interpreted as x, y, radius. The radius is always interpreted in the units of the plot's horizontal axis (x or x2). The scale on y and the aspect ratio of the plot are both ignored. If only two columns are present, the radius is taken from set style circle. In this case the radius may be given in graph or screen coordinates. By default a full circle will be drawn. It is possible to plot arc segments instead of full circles by specifying a start and end angle in the 4th and 5th columns. An optional 4th or 6th column can specify per-circle color. The start and end angles of the circle segments must be specified in degrees.

Circles

Fig. 7 Plot style circles

Examples:

   # draws circles whose area is proportional to the value in column 3
   set style fill transparent solid 0.2 noborder
   plot 'data' using 1:2:(sqrt($3)) with circles, \
        'data' using 1:2 with linespoints

   # draws Pac-men instead of circles
   plot 'data' using 1:2:(10):(40):(320) with circles

   # draw a pie chart with inline data
   set xrange [-15:15]
   set style fill transparent solid 0.9 noborder
   plot '-' using 1:2:3:4:5:6 with circles lc var
   0    0    5    0    30    1
   0    0    5   30    70    2
   0    0    5   70   120    3
   0    0    5  120   230    4
   0    0    5  230   360    5
   e

The result is similar to using a points plot with variable size points and pointstyle 7, except that the circles will scale with the x axis range. See also set object circle (p. 179) and fillstyle (p. 202).

Ellipses

The ellipses style plots an ellipse at each data point. This style is only relevant for 2D plotting. Each ellipse is described in terms of its center, major and minor diameters, and the angle between its major diameter and the x axis.

Ellipses

Fig. 8 Plot style ellipses

    2 columns: x y
    3 columns: x y major_diam
    4 columns: x y major_diam minor_diam
    5 columns: x y major_diam minor_diam angle

If only two input columns are present, they are taken as the coordinates of the centers, and the ellipses will be drawn with the default extent (see set style ellipse (p. 206)). The orientation of the ellipse, which is defined as the angle between the major diameter and the plot's x axis, is taken from the default ellipse style (see set style ellipse (p. 206)). If three input columns are provided, the third column is used for both diameters. The orientation angle defaults to zero. If four columns are present, they are interpreted as x, y, major diameter, minor diameter. Note that these are diameters, not radii. An optional 5th column may be used to specify the orientation angle in degrees. The ellipses will also be drawn with their default extent if either of the supplied diameters in the 3-4-5 column form is negative.

In all of the above cases, optional variable color data may be given in an additional last (3th, 4th, 5th or 6th) column. See colorspec (p. 40) for further information.

By default, the major diameter is interpreted in the units of the plot's horizontal axis (x or x2) while the minor diameter in that of the vertical (y or y2). This implies that if the x and y axis scales are not equal, then the major/minor diameter ratio will no longer be correct after rotation. This behavior can be changed with the units keyword, however.

There are three alternatives: if units xy is included in the plot specification, the axes will be scaled as described above. units xx ensures that both diameters are interpreted in units of the x axis, while units yy means that both diameters are interpreted in units of the y axis. In the latter two cases the ellipses will have the correct aspect ratio, even if the plot is resized.

If units is omitted, the default setting will be used, which is equivalent to units xy. This can be redefined by set style ellipse.

Example (draws ellipses, cycling through the available line types):

   plot 'data' using 1:2:3:4:(0):0 with ellipses

See also set object ellipse (p. 178), set style ellipse (p. 206) and fillstyle (p. 202).

Dots

The dots style plots a tiny dot at each point; this is useful for scatter plots with many points. Either 1 or 2 columns of input data are required in 2D. Three columns are required in 3D.

For some terminals (post, pdf) the size of the dot can be controlled by changing the linewidth.

Dots

Fig. 9 Plot style dots

    1 column    y         # x is row number
    2 columns:  x  y
    3 columns:  x  y  z   # 3D only (splot)

Filledcurves

The filledcurves style is only relevant to 2D plotting. Three variants are possible. The first two variants require either a function or two columns of input data, and may be further modified by the options listed below.

Filledcurves

Fig. 10 Plot style filledcurves

Syntax:

   plot ... with filledcurves [option]

where the option can be one of the following

   [closed | {above | below}
   {x1 | x2 | y1 | y2 | r}[=<a>] | xy=<x>,<y>]

The first variant, closed, treats the curve itself as a closed polygon. This is the default if there are two columns of input data.

The second variant is to fill the area between the curve and a given axis, a horizontal or vertical line, or a point.

   filledcurves closed   ... just filled closed curve,
   filledcurves x1       ... x1 axis,
   filledcurves x2       ... x2 axis, etc for y1 and y2 axes,
   filledcurves y1=0     ... line y=0 (at y1 axis) ie parallel to x1 axis,
   filledcurves y2=42    ... line y=42 (at y2 axis) ie parallel to x2, etc,
   filledcurves xy=10,20 ... point 10,20 of x1,y1 axes (arc-like shape).
   filledcurves above r=1.5  the area of a polar plot outside radius 1.5

The third variant requires three columns of input data: the x coordinate and two y coordinates corresponding to two curves sampled at the same set of x coordinates; the area between the two curves is filled. This is the default if there are three or more columns of input data.

    3 columns:  x  y1  y2

Example of filling the area between two input curves.

fill between curves demo.

   plot 'data' using 1:2:3 with filledcurves

The above and below options apply both to commands of the form

   ... filledcurves above {x1|x2|y1|y2|r}=<val>

and to commands of the form

   ... using 1:2:3 with filledcurves below
In either case the option limits the filled area to one side of the bounding line or curve.

Note: Not all terminal types support this plotting mode.

Zooming a filled curve drawn from a datafile may produce empty or incorrect areas because gnuplot is clipping points and lines, and not areas.

If the values of <a>, <x>, <y> are out of the drawing boundary, then they are moved to the graph boundary. Then the actually filled area in the case of option xy=<x>,<y> will depend on xrange and yrange.

Financebars

The financebars style is only relevant for 2D data plotting of financial data. It requires 1 x coordinate (usually a date) and 4 y values (prices).

Financebars

Fig. 11 Plot style financebars

    5 columns:   date  open  low  high  close

An additional (6th) input column may be used to provide variable (per-record) color information (see linecolor (p. 41) and rgbcolor variable (p. 42)).

The symbol is a vertical line segment, located horizontally at the x coordinate and limited vertically by the high and low prices. A horizontal tic on the left marks the opening price and one on the right marks the closing price. The length of these tics may be changed by set bars. The symbol will be unchanged if the high and low prices are interchanged. See set bars (p. 133) and candlesticks (p. 57), and also the finance demo.

Fsteps

The fsteps style is only relevant to 2D plotting. It connects consecutive points with two line segments: the first from (x1,y1) to (x1,y2) and the second from (x1,y2) to (x2,y2). The input column requires are the same as for plot styles lines and points. The difference between fsteps and steps is that fsteps traces first the change in y and then the change in x. steps traces first the change in x and then the change in y.

Fsteps

Fig. 12 Plot style fsteps

See also steps demo.

Fillsteps

The fillsteps style is exactly like steps except that the area between the curve and y=0 is filled in the current fill style. See steps (p. 71).

Histeps

The histeps style is only relevant to 2D plotting. It is intended for plotting histograms. Y-values are assumed to be centered at the x-values; the point at x1 is represented as a horizontal line from ((x0+x1)/2,y1) to ((x1+x2)/2,y1). The lines representing the end points are extended so that the step is centered on at x. Adjacent points are connected by a vertical line at their average x, that is, from ((x1+x2)/2,y1) to ((x1+x2)/2,y2). The input column requires are the same as for plot styles lines and points.

Histeps

Fig. 13 Plot style histeps

If autoscale is in effect, it selects the xrange from the data rather than the steps, so the end points will appear only half as wide as the others. See also steps demo.

histeps is only a plotting style; gnuplot does not have the ability to create bins and determine their population from some data set.

Histograms

The histograms style is only relevant to 2D plotting. It produces a bar chart from a sequence of parallel data columns. Each element of the plot command must specify a single input data source (e.g. one column of the input file), possibly with associated tic values or key titles. Four styles of histogram layout are currently supported.

     set style histogram clustered {gap <gapsize>}
     set style histogram errorbars {gap <gapsize>} {<linewidth>}
     set style histogram rowstacked
     set style histogram columnstacked

The default style corresponds to set style histogram clustered gap 2. In this style, each set of parallel data values is collected into a group of boxes clustered at the x-axis coordinate corresponding to their sequential position (row #) in the selected datafile columns. Thus if <n> datacolumns are selected, the first cluster is centered about x=1, and contains <n> boxes whose heights are taken from the first entry in the corresponding <n> data columns. This is followed by a gap and then a second cluster of boxes centered about x=2 corresponding to the second entry in the respective data columns, and so on. The default gap width of 2 indicates that the empty space between clusters is equivalent to the width of 2 boxes. All boxes derived from any one column are given the same fill color and/or pattern (see set style fill (p. 202)).

Each cluster of boxes is derived from a single row of the input data file. It is common in such input files that the first element of each row is a label. Labels from this column may be placed along the x-axis underneath the appropriate cluster of boxes with the xticlabels option to using.

The errorbars style is very similar to the clustered style, except that it requires additional columns of input for each entry. The first column holds the height (y value) of that box, exactly as for the clustered style.

    2 columns:        y yerr          bar extends from y-yerr to y+err
    3 columns:        y ymin yman     bar extends from ymin to ymax

The appearance of the error bars is controlled by the current value of set bars and by the optional <linewidth> specification.

Two styles of stacked histogram are supported, chosen by the command set style histogram {rowstacked|columnstacked}. In these styles the data values from the selected columns are collected into stacks of boxes. Positive values stack upwards from y=0; negative values stack downwards. Mixed positive and negative values will produce both an upward stack and a downward stack. The default stacking mode is rowstacked.

The rowstacked style places a box resting on the x-axis for each data value in the first selected column; the first data value results in a box a x=1, the second at x=2, and so on. Boxes corresponding to the second and subsequent data columns are layered on top of these, resulting in a stack of boxes at x=1 representing the first data value from each column, a stack of boxes at x=2 representing the second data value from each column, and so on. All boxes derived from any one column are given the same fill color and/or pattern (see set style fill (p. 202)).

The columnstacked style is similar, except that each stack of boxes is built up from a single data column. Each data value from the first specified column yields a box in the stack at x=1, each data value from the second specified column yields a box in the stack at x=2, and so on. In this style the color of each box is taken from the row number, rather than the column number, of the corresponding data field.

Box widths may be modified using the set boxwidth command. Box fill styles may be set using the set style fill command.

Histograms always use the x1 axis, but may use either y1 or y2. If a plot contains both histograms and other plot styles, the non-histogram plot elements may use either the x1 or the x2 axis.

Examples: Suppose that the input file contains data values in columns 2, 4, 6, ... and error estimates in columns 3, 5, 7, ... This example plots the values in columns 2 and 4 as a histogram of clustered boxes (the default style). Because we use iteration in the plot command, any number of data columns can be handled in a single command. See iteration (p. 90).

Histogram cluster

Fig. 14 Plot style histogram cluster

     set boxwidth 0.9 relative
     set style data histograms
     set style histogram cluster
     set style fill solid 1.0 border lt -1
     plot for [COL=2:4:2] 'file.dat' using COL

This will produce a plot with clusters of two boxes (vertical bars) centered at each integral value on the x axis. If the first column of the input file contains labels, they may be placed along the x-axis using the variant command

     plot for [COL=2:4:2] 'file.dat' using COL:xticlabels(1)

If the file contains both magnitude and range information for each value, then error bars can be added to the plot. The following commands will add error bars extending from (y-<error>) to (y+<error>), capped by horizontal bar ends drawn the same width as the box itself. The error bars and bar ends are drawn with linewidth 2, using the border linetype from the current fill style.

Histogram errorbars

Fig. 15 Plot style histogram errorbars

     set bars fullwidth
     set style fill solid 1 border lt -1
     set style histogram errorbars gap 2 lw 2
     plot for [COL=2:4:2] 'file.dat' using COL:COL+1

To plot the same data as a rowstacked histogram. Just to be different, this example lists the separate columns explicitly rather than using iteration.

Histogram rowstacked

Fig. 16 Plot style histogram rowstacked

     set style histogram rowstacked
     plot 'file.dat' using 2, '' using 4:xtic(1)

This will produce a plot in which each vertical bar corresponds to one row of data. Each vertical bar contains a stack of two segments, corresponding in height to the values found in columns 2 and 4 of the datafile.

Finally, the commands

Histogram columnstacked

Fig. 17 Plot style histogram columnstacked

     set style histogram columnstacked
     plot 'file.dat' using 2, '' using 4

will produce two vertical stacks, one for each column of data. The stack at x=1 will contain a box for each entry in column 2 of the datafile. The stack at x=2 will contain a box for each parallel entry in column 4 of the datafile. Because this interchanges gnuplot's usual interpretation of input rows and columns, the specification of key titles and x-axis tic labels must also be modified accordingly. See the comments given below.

     set style histogram columnstacked
     plot '' u 5:key(1)            # uses first column to generate key titles
     plot '' u 5 title columnhead  # uses first row to generate xtic labels

Note that the two examples just given present exactly the same data values, but in different formats.

Newhistogram

Syntax:

    newhistogram {"<title>"} {lt <linetype>} {fs <fillstyle>} {at <x-coord>}

More than one set of histograms can appear in a single plot. In this case you can force a gap between them, and a separate label for each set, by using the newhistogram command. For example

     set style histogram  cluster
     plot newhistogram "Set A", 'a' using 1, '' using 2, '' using 3, \
          newhistogram "Set B", 'b' using 1, '' using 2, '' using 3

The labels "Set A" and "Set B" will appear beneath the respective sets of histograms, under the overall x axis label.

The newhistogram command can also be used to force histogram coloring to begin with a specific color (linetype). By default colors will continue to increment successively even across histogram boundaries. Here is an example using the same coloring for multiple histograms

     plot newhistogram "Set A" lt 4, 'a' using 1, '' using 2, '' using 3, \
          newhistogram "Set B" lt 4, 'b' using 1, '' using 2, '' using 3

Similarly you can force the next histogram to begin with a specified fillstyle. If the fillstyle is set to pattern, then the pattern used for filling will be incremented automatically.

The at <x-coord> option sets the x coordinate position of the following histogram to <x-coord>. For example

Newhistogram

Fig. 18 Plot style newhistogram

      set style histogram cluster
      set style data histogram
      set style fill solid 1.0 border -1
      set xtic 1 offset character 0,0.3
      plot newhistogram "Set A", \
           'file.dat' u 1 t 1, '' u 2 t 2, \
           newhistogram "Set B" at 8, \
           'file.dat' u 2 t 2, '' u 2 t 2

will position the second histogram to start at x=8.

Automated iteration over multiple columns

If you want to create a histogram from many columns of data in a single file, it is very convenient to use the plot iteration feature. See iteration (p. 90). For example, to create stacked histograms of the data in columns 3 through 8

     set style histogram columnstacked
     plot for [i=3:8] "datafile" using i title columnhead

Image

The image, rgbimage, and rgbalpha plotting styles all project a uniformly sampled grid of data values onto a plane in either 2D or 3D. The input data may be an actual bitmapped image, perhaps converted from a standard format such as PNG, or a simple array of numerical values.

This figure illustrates generation of a heat map from an array of scalar values. The current palette is used to map each value onto the color assigned to the corresponding pixel.

Heat map

Fig. 19 Plotting a heat map

     plot '-' matrix with image
     5 4 3 1 0
     2 2 0 0 1
     0 0 0 1 0
     0 1 2 4 3
     e
     e

Each pixel (data point) of the input 2D image will become a rectangle or parallelipiped in the plot. The coordinates of each data point will determine the center of the parallelipiped. That is, an M x N set of data will form an image with M x N pixels. This is different from the pm3d plotting style, where an M x N set of data will form a surface of (M-1) x (N-1) elements. The scan directions for a binary image data grid can be further controlled by additional keywords. See binary keywords flipx (p. 98), keywords center (p. 99), and keywords rotate (p. 99).

RGB Image 3D

Fig. 20 Plotting a RGB image in 3D

Image data can be scaled to fill a particular rectangle within a 2D plot coordinate system by specifying the x and y extent of each pixel. See binary keywords dx (p. 98) and dy (p. 98).

Scaled image

Fig. 21 Plotting scaled images

To generate the figure above, the same input image was placed multiple times, each with a specified dx, dy, and origin. The input PNG image of a building is 50x128 pixels. The tall building was drawn by mapping this using dx=0.5 dy=1.5. The short building used a mapping dx=0.5 dy=0.35.

The image style handles input pixels containing a grayscale or color palette value. Thus 2D plots (plot command) require 3 columns of data (x,y,value), while 3D plots (splot command) require 4 columns of data (x,y,z,value).

The rgbimage style handles input pixels that are described by three separate values for the red, green, and blue components. Thus 5D data (x,y,r,g,b) is needed for plot and 6D data (x,y,z,r,g,b) for splot. The individual red, green, and blue components are assumed to lie in the range [0:255].

The rgbalpha style handles input pixels that contain alpha channel (transparency) information in addition to the red, green, and blue components. Thus 6D data (x,y,r,g,b,a) is needed for plot and 7D data (x,y,z,r,g,b,a) for splot. The r, g, b, and alpha components are assumed to lie in the range [0:255].

Transparency

The rgbalpha plotting style assumes that each pixel of input data contains an alpha value in the range [0:255]. A pixel with alpha = 0 is purely transparent and does not alter the underlying contents of the plot. A pixel with alpha = 255 is purely opaque. All terminal types can handle these two extreme cases. A pixel with 0 < alpha < 255 is partially transparent. Only a few terminal types can handle this correctly; other terminals will approximate this by treating alpha as being either 0 or 255.

Image failsafe

Some terminal drivers provide code to optimize rendering of image data within a rectangular 2D area. However this code is known to be imperfect. This optimized code may be disabled by using the keyword failsafe. E.g.

     plot 'data' with image failsafe

Impulses

The impulses style displays a vertical line from y=0 to the y value of each point (2D) or from z=0 to the z value of each point (3D). Note that the y or z values may be negative. Data from additional columns can be used to control the color of each impulse. To use this style effectively in 3D plots, it is useful to choose thick lines (linewidth > 1). This approximates a 3D bar chart.

Impulses

Fig. 22 Plot style impulses

    1 column:   y
    2 columns:  x  y     # line from [x,0] to [x,y]  (2D)
    3 columns:  x  y  z  # line from [x,y,0] to [x,y,z] (3D)

Labels

The labels style reads coordinates and text from a data file and places the text string at the corresponding 2D or 3D position. 3 or 4 input columns of basic data are required. Additional input columns may be used to provide information such as variable font size or text color (see rgbcolor variable (p. 42)).

Labels

Fig. 23 Plot style labels

    3 columns:  x  y  string    # 2D version
    4 columns:  x  y  z  string # 3D version

The font, color, rotation angle and other properties of the printed text may be specified as additional command options (see set label (p. 163)). The example below generates a 2D plot with text labels constructed from the city whose name is taken from column 1 of the input file, and whose geographic coordinates are in columns 4 and 5. The font size is calculated from the value in column 3, in this case the population.

 CityName(String,Size) = sprintf("{/=%d %s}", Scale(Size), String)
 plot 'cities.dat' using 5:4:(CityName(stringcolumn(1),$3)) with labels

If we did not want to adjust the font size to a different size for each city name, the command would be much simpler:

 plot 'cities.dat' using 5:4:1 with labels font "Times,8"

The labels style can also be used in 3D plots. In this case four input column specifiers are required, corresponding to X Y Z and text.

 splot 'datafile' using 1:2:3:4 with labels

See also datastrings (p. 25), set style data (p. 201).

Lines

The lines style connects adjacent points with straight line segments. It may be used in either 2D or 3D plots. The basic form requires 1, 2, or 3 columns of input data. Additional input columns may be used to provide information such as variable line color (see rgbcolor variable (p. 42)).

Lines

Fig. 24 Plot style lines

2D form

    1 column:   y       # implicit x from row number
    2 columns:  x  y
3D form
    1 column:   z       # implicit x from row, y from index
    3 columns:  x  y  z

See also linetype (p. 166), linewidth (p. 204), and linestyle (p. 204).

Linespoints

The linespoints style connects adjacent points with straight line segments and then goes back to draw a small symbol at each point. The command set pointsize may be used to change the default size of the points. 1 or 2 columns of basic input data are required in 2D plots; 1 or 3 columns are required if 3D plots. See style lines (p. 70). Additional input columns may be used to provide information such as variable point size or line color.

Linespoints

Fig. 25 Plot style linespoints

The pointinterval (short form pi) property of the linetype can be used to control whether or not every point in the plot is given a symbol. For example, 'with lp pi 3' will draw line segments through every data point, but will only place a symbol on every 3rd point. A negative value for pointinterval will erase the portion of line segment that passes underneath the symbol. The size of the erased portion is controlled by set pointintervalbox.

linespoints may be abbreviated lp.

Points

The points style displays a small symbol at each point. The command set pointsize may be used to change the default size of the points. 1 or 2 columns of basic input data are required in 2D plots; 1 or 3 columns are required in 3D plots. See style lines (p. 70). Additional input columns may be used to provide information such as variable point size or variable point color.

Points

Fig. 26 Plot style points

Polar

Polar plots are not really a separate plot style but are listed here for completeness. The option set polar tells gnuplot to interpret input 2D coordinates as <angle>,<radius> rather than <x>,<y>. Many, but not all, 2D plotting styles work in polar mode. The figure shows a combination of plot styles lines and filledcurves. See set polar (p. 194), set rrange (p. 196), set size square (p. 197).

Polar

Fig. 27 Plot style polar

Steps

The steps style is only relevant to 2D plotting. It connects consecutive points with two line segments: the first from (x1,y1) to (x2,y1) and the second from (x2,y1) to (x2,y2). The input column requires are the same as for plot styles lines and points. The difference between fsteps and steps is that fsteps traces first the change in y and then the change in x. steps traces first the change in x and then the change in y. To fill the area between the curve and the baseline at y=0, use fillsteps. See also steps demo.

Steps

Fig. 28 Plot style steps

Rgbalpha

See image (p. 67).

Rgbimage

See image (p. 67).

Vectors

The 2D vectors style draws a vector from (x,y) to (x+xdelta,y+ydelta). The 3D vectors style is similar, but requires six columns of basic data. A small arrowhead is drawn at the end of each vector.

    4 columns:  x  y  xdelta  ydelta
    6 columns:  x  y  z  xdelta  ydelta  zdelta

In both cases, an additional input column (5th in 2D, 7th in 3D) may be used to provide variable (per-datapoint) color information. (see linecolor (p. 41) and rgbcolor variable (p. 42)).

splot with vectors is supported only for set mapping cartesian.

The keywords "with vectors" may be followed by an in-line arrow style specifications, a reference to a predefined arrow style, or a request to read the index of the desired arrow style for each vector from a separate column. Note: If you choose "arrowstyle variable" it will fill in all arrow properties at the time the corresponding vector is drawn; you cannot mix this keyword with other line or arrow style qualifiers in the plot command.

    plot ... with vectors filled heads
    plot ... with vectors arrowstyle 3
    plot ... using 1:2:3:4:5 with vectors arrowstyle variable

See arrowstyle (p. 199) for more details.

Example:

     plot 'file.dat' using 1:2:3:4 with vectors head filled lt 2
     splot 'file.dat' using 1:2:3:(1):(1):(1) with vectors filled head lw 2

set clip one and set clip two affect vectors drawn in 2D. Please see set clip (p. 137) and arrowstyle (p. 199).

Xerrorbars

The xerrorbars style is only relevant to 2D data plots. xerrorbars is like points, except that a horizontal error bar is also drawn. At each point (x,y), a line is drawn from (xlow,y) to (xhigh,y) or from (x-xdelta,y) to (x+xdelta,y), depending on how many data columns are provided. A tic mark is placed at the ends of the error bar (unless set bars is used — see set bars (p. 133) for details). The basic style requires either 3 or 4 columns:

Xerrorbars

Fig. 29 Plot style xerrorbars

    3 columns:  x  y  xdelta
    4 columns:  x  y  xlow  xhigh

An additional input column (4th or 5th) may be used to provide information such as variable point color.

Xyerrorbars

The xyerrorbars style is only relevant to 2D data plots. xyerrorbars is like points, except that horizontal and vertical error bars are also drawn. At each point (x,y), lines are drawn from (x,y-ydelta) to (x,y+ydelta) and from (x-xdelta,y) to (x+xdelta,y) or from (x,ylow) to (x,yhigh) and from (xlow,y) to (xhigh,y), depending upon the number of data columns provided. A tic mark is placed at the ends of the error bar (unless set bars is used — see set bars (p. 133) for details). Either 4 or 6 input columns are required.

Xyerrorbars

Fig. 30 Plot style xyerrorbars

    4 columns:  x  y  xdelta  ydelta
    6 columns:  x  y  xlow  xhigh  ylow  yhigh

If data are provided in an unsupported mixed form, the using filter on the plot command should be used to set up the appropriate form. For example, if the data are of the form (x,y,xdelta,ylow,yhigh), then you can use

     plot 'data' using 1:2:($1-$3):($1+$3):4:5 with xyerrorbars

An additional input column (5th or 7th) may be used to provide variable (per-datapoint) color information.

Yerrorbars

The yerrorbars (or errorbars) style is only relevant to 2D data plots. yerrorbars is like points, except that a vertical error bar is also drawn. At each point (x,y), a line is drawn from (x,y-ydelta) to (x,y+ydelta) or from (x,ylow) to (x,yhigh), depending on how many data columns are provided. A tic mark is placed at the ends of the error bar (unless set bars is used — see set bars (p. 133) for details). Either 3 or 4 input columns are required.

Yerrorbars

Fig. 31 Plot style yerrorbars

    3 columns:  x  y  ydelta
    4 columns:  x  y  ylow  yhigh

An additional input column (4th or 5th) may be used to provide information such as variable point color.

See also errorbar demo.

Xerrorlines

The xerrorlines style is only relevant to 2D data plots. xerrorlines is like linespoints, except that a horizontal error line is also drawn. At each point (x,y), a line is drawn from (xlow,y) to (xhigh,y) or from (x-xdelta,y) to (x+xdelta,y), depending on how many data columns are provided. A tic mark is placed at the ends of the error bar (unless set bars is used — see set bars (p. 133) for details). The basic style requires either 3 or 4 columns:

Xerrorlines

Fig. 32 Plot style xerrorlines

    3 columns:  x  y  xdelta
    4 columns:  x  y  xlow  xhigh

An additional input column (4th or 5th) may be used to provide information such as variable point color.

Xyerrorlines

The xyerrorlines style is only relevant to 2D data plots. xyerrorlines is like linespoints, except that horizontal and vertical error bars are also drawn. At each point (x,y), lines are drawn from (x,y-ydelta) to (x,y+ydelta) and from (x-xdelta,y) to (x+xdelta,y) or from (x,ylow) to (x,yhigh) and from (xlow,y) to (xhigh,y), depending upon the number of data columns provided. A tic mark is placed at the ends of the error bar (unless set bars is used — see set bars (p. 133) for details). Either 4 or 6 input columns are required.

Xyerrorlines

Fig. 33 Plot style xyerrorlines

    4 columns:  x  y  xdelta  ydelta
    6 columns:  x  y  xlow  xhigh  ylow  yhigh

If data are provided in an unsupported mixed form, the using filter on the plot command should be used to set up the appropriate form. For example, if the data are of the form (x,y,xdelta,ylow,yhigh), then you can use

     plot 'data' using 1:2:($1-$3):($1+$3):4:5 with xyerrorlines

An additional input column (5th or 7th) may be used to provide variable (per-datapoint) color information.

Yerrorlines

The yerrorlines (or errorlines) style is only relevant to 2D data plots. yerrorlines is like linespoints, except that a vertical error line is also drawn. At each point (x,y), a line is drawn from (x,y-ydelta) to (x,y+ydelta) or from (x,ylow) to (x,yhigh), depending on how many data columns are provided. A tic mark is placed at the ends of the error bar (see set bars (p. 133) for details). Either 3 or 4 input columns are required.

Yerrorlines

Fig. 34 Plot style yerrorlines

    3 columns:  x  y  ydelta
    4 columns:  x  y  ylow  yhigh

An additional input column (4th or 5th) may be used to provide information such as variable point color.

See also errorbar demo.

3D (surface) plots

Surface plots are generated using the splot command rather than the plot command. The style with lines draws a surface made from a grid of lines. Solid surfaces can be drawn using the style with pm3d. Usually the surface is displayed at some arbitrary viewing angle, such that it clearly represents a 3D surface. In this case the X, Y, and Z axes are all visible in the plot. The illusion of 3D is enhanced by choosing hidden line removal or depth-sorted surface elements. See hidden3d (p. 156) and the depthorder (p. 184) option of set pm3d (p. 182).

Surface

Fig. 35 Plot style pm3d

The splot command can also calculate and draw contour lines corresponding to constant Z values. These contour lines may be drawn onto the surface itself, or projected onto the XY plane. See set contour (p. 141).
Surface + contour

Fig. 36 Plot style pm3d + contour

2D projection (set view map)

An important special case of the splot command is to map the Z coordinate onto a 2D surface by projecting the plot along the Z axis. See set view map (p. 213). This plot mode can be used to generate contour plots and heat maps.

Set view map

Fig. 37 Plot style set view map

Part III
Commands

This section lists the commands acceptable to gnuplot in alphabetical order. Printed versions of this document contain all commands; the text available interactively may not be complete. Indeed, on some systems there may be no commands at all listed under this heading.

Note that in most cases unambiguous abbreviations for command names and their options are permissible, i.e., "p f(x) w li" instead of "plot f(x) with lines".

In the syntax descriptions, braces ({}) denote optional arguments and a vertical bar (|) separates mutually exclusive choices.

Cd

The cd command changes the working directory.

Syntax:

     cd '<directory-name>'

The directory name must be enclosed in quotes.

Examples:

     cd 'subdir'
     cd ".."

It is recommended that Windows users use single-quotes, because backslash [\] has special significance inside double-quotes and has to be escaped. For example,

     cd "c:\newdata"
fails, but
     cd 'c:\newdata'
     cd "c:\\newdata"
work as expected.

Call

The call command is identical to the load command with one exception: you can have up to ten additional parameters to the command (delimited according to the standard parser rules) which can be substituted into the lines read from the file. As each line is read from the called input file, it is scanned for the sequence $ (dollar-sign) followed by a digit (0–9). If found, the sequence is replaced by the corresponding parameter from the call command line. If the parameter was specified as a string in the call line, it is substituted without its enclosing quotes. Sequence $# is replaced by the number of passed parameters. $ followed by any character will be that character; e.g. use $$ to get a single $. Providing more than ten parameters on the call command line will cause an error. A parameter that was not provided substitutes as nothing. Files being called may themselves contain call or load commands.

Syntax:

     call "<input-file>" <parameter-0> <parm-1> ... <parm-9>

The name of the input file must be enclosed in quotes, and it is recommended that parameters are similarly enclosed in quotes (future versions of gnuplot may treat quoted and unquoted arguments differently).

Example:

If the file 'calltest.gp' contains the line:

     print "argc=$# p0=$0 p1=$1 p2=$2 p3=$3 p4=$4 p5=$5 p6=$6 p7=x$7x"

entering the command:

     call 'calltest.gp' "abcd" 1.2 + "'quoted'" -- "$2"

will display:

     argc=7 p0=abcd p1=1.2 p2=+ p3='quoted' p4=- p5=- p6=$2 p7=xx

NOTE: there is a clash in syntax with the datafile using callback operator. Use $$n or column(n) to access column n from a datafile inside a called datafile plot.

Clear

The clear command erases the current screen or output device as specified by set output. This usually generates a formfeed on hardcopy devices. Use set terminal to set the device type.

For some terminals clear erases only the portion of the plotting surface defined by set size, so for these it can be used in conjunction with set multiplot to create an inset.

Example:

     set multiplot
     plot sin(x)
     set origin 0.5,0.5
     set size 0.4,0.4
     clear
     plot cos(x)
     unset multiplot

Please see set multiplot (p. 173), set size (p. 197), and set origin (p. 180) for details of these commands.

Do

Syntax:

     do for <iteration-spec> {
          <commands>
          <commands>
     }
Execute a sequence of commands multiple times. The commands must be enclosed in curly brackets, and the opening "{" must be on the same line as the do keyword. This command cannot be used with old-style (un-bracketed) if/else statements. See if (p. 89). For examples of iteration specifiers, see iteration (p. 90). Example:
     set multiplot layout 2,2
     do for [name in "A B C D"] {
         filename = name . ".dat"
         set title sprintf("Condition %s",name)
         plot filename title name
     }
     unset multiplot

Evaluate

The evaluate command executes the commands given as an argument string. Newline characters are not allowed within the string.

Syntax:

     eval <string expression>

This is especially useful for a repetition of similar commands.

Example:

     set_label(x, y, text) \
       = sprintf("set label '%s' at %f, %f point pt 5", text, x, y)
     eval set_label(1., 1., 'one/one')
     eval set_label(2., 1., 'two/one')
     eval set_label(1., 2., 'one/two')

Please see substitution macros (p. 49) for another way to execute commands from a string.

Exit

The commands exit and quit, as well as the END-OF-FILE character (usually Ctrl-D) terminate input from the current input stream: terminal session, pipe, and file input (pipe).

If input streams are nested (inherited load scripts), then reading will continue in the parent stream. When the top level stream is closed, the program itself will exit.

The command exit gnuplot will immediately and unconditionally cause gnuplot to exit even if the input stream is multiply nested. In this case any open output files may not be completed cleanly. Example of use:

     bind "ctrl-x" "unset output; exit gnuplot"

See help for batch/interactive (p. 22) for more details.

Fit

The fit command can fit a user-supplied expression to a set of data points (x,z) or (x,y,z), using an implementation of the nonlinear least-squares (NLLS) Marquardt-Levenberg algorithm. Any user-defined variable occurring in the expression may serve as a fit parameter, but the return type of the expression must be real.

Syntax:

     fit {<ranges>} <expression>
         '<datafile>' {datafile-modifiers}
         via '<parameter file>' | <var1>{,<var2>,...}

Ranges may be specified to temporarily limit the data which is to be fitted; any out-of-range data points are ignored. The syntax is

     [{dummy_variable=}{<min>}{:<max>}],
analogous to plot; see plot ranges (p. 116).

<expression> is any valid gnuplot expression, although it is usual to use a previously user-defined function of the form f(x) or f(x,y).

<datafile> is treated as in the plot command. All the plot datafile modifiers (using, every,...) except smooth and the deprecated thru are applicable to fit. See plot datafile (p. 99).

The default data formats for fitting functions with a single independent variable, z=f(x), are z or x:z. That is, if there is only a single column then it is the dependent variable and the line numbers is the independent variable. If there are two columns, the first is the independent variable and the second is the dependent variable.

Those formats can be changed with the datafile using qualifier, for example to take the z value from a different column or to calculate it from several columns. A third using qualifier (a column number or an expression), if present, is interpreted as the standard deviation of the corresponding z value and is used to compute a weight for the datum, 1/s**2. Otherwise, all data points are weighted equally, with a weight of one. Note that if you don't specify a using option at all, no z standard deviations are read from the datafile even if it does have a third column, so you'll always get unit weights.

To fit a function with two independent variables, z=f(x,y), the required format is using with four items, x:y:z:s. The complete format must be given — no default columns are assumed for a missing token. Weights for each data point are evaluated from 's' as above. If error estimates are not available, a constant value can be specified as a constant expression (see plot datafile using (p. 109)), e.g., using 1:2:3:(1).

The fit function may have up to five independent variables. There must be two more using qualifiers than there are independent variables, unless there is only one variable. The allowed formats, and the default dummy variable names, are as follows:

     z
     x:z
     x:z:s
     x:y:z:s
     x:y:t:z:s
     x:y:t:u:z:s
     x:y:t:u:v:z:s

The dummy variable names may be changed with ranges as noted above. The first range corresponds to the first using spec, etc. A range may also be given for z (the dependent variable), but that name cannot be changed.

Multiple datasets may be simultaneously fit with functions of one independent variable by making y a 'pseudo-variable', e.g., the dataline number, and fitting as two independent variables. See fit multi-branch (p. 86).

The via qualifier specifies which parameters are to be adjusted, either directly, or by referencing a parameter file.

Examples:

     f(x) = a*x**2 + b*x + c
     g(x,y) = a*x**2 + b*y**2 + c*x*y
     FIT_LIMIT = 1e-6
     fit f(x) 'measured.dat' via 'start.par'
     fit f(x) 'measured.dat' using 3:($7-5) via 'start.par'
     fit f(x) './data/trash.dat' using 1:2:3 via a, b, c
     fit g(x,y) 'surface.dat' using 1:2:3:(1) via a, b, c
     fit a0 + a1*x/(1 + a2*x/(1 + a3*x)) 'measured.dat' via a0,a1,a2,a3
     fit a*x + b*y 'surface.dat' using 1:2:3:(1) via a,b
     fit [*:*][yaks=*:*] a*x+b*yaks 'surface.dat' u 1:2:3:(1) via a,b
     fit a*x + b*y + c*t 'foo.dat' using 1:2:3:4:(1) via a,b,c
     h(x,y,t,u,v) = a*x + b*y + c*t + d*u + e*v
     fit h(x,y,t,u,v) 'foo.dat' using 1:2:3:4:5:6:(1) via a,b,c,d,e

After each iteration step, detailed information about the current state of the fit is written to the display. The same information about the initial and final states is written to a log file, "fit.log". This file is always appended to, so as to not lose any previous fit history; it should be deleted or renamed as desired. By using the command set fit logfile, the name of the log file can be changed.

If gnuplot was built with this option, and you activated it using set fit errorvariables, the error for each fitted parameter will be stored in a variable named like the parameter, but with "_err" appended. Thus the errors can be used as input for further computations.

The fit may be interrupted by pressing Ctrl-C. After the current iteration completes, you have the option to (1) stop the fit and accept the current parameter values, (2) continue the fit, (3) execute a gnuplot command as specified by the environment variable FIT_SCRIPT. The default for FIT_SCRIPT is replot, so if you had previously plotted both the data and the fitting function in one graph, you can display the current state of the fit.

Once fit has finished, the update command may be used to store final values in a file for subsequent use as a parameter file. See update (p. 239) for details.

Adjustable parameters

There are two ways that via can specify the parameters to be adjusted, either directly on the command line or indirectly, by referencing a parameter file. The two use different means to set initial values.

Adjustable parameters can be specified by a comma-separated list of variable names after the via keyword. Any variable that is not already defined is created with an initial value of 1.0. However, the fit is more likely to converge rapidly if the variables have been previously declared with more appropriate starting values.

In a parameter file, each parameter to be varied and a corresponding initial value are specified, one per line, in the form

     varname = value

Comments, marked by '#', and blank lines are permissible. The special form

     varname = value       # FIXED

means that the variable is treated as a 'fixed parameter', initialized by the parameter file, but not adjusted by fit. For clarity, it may be useful to designate variables as fixed parameters so that their values are reported by fit. The keyword # FIXED has to appear in exactly this form.

Short introduction

fit is used to find a set of parameters that 'best' fits your data to your user-defined function. The fit is judged on the basis of the sum of the squared differences or 'residuals' (SSR) between the input data points and the function values, evaluated at the same places. This quantity is often called 'chisquare' (i.e., the Greek letter chi, to the power of 2). The algorithm attempts to minimize SSR, or more precisely, WSSR, as the residuals are 'weighted' by the input data errors (or 1.0) before being squared; see fit error_estimates (p. 83) for details.

That's why it is called 'least-squares fitting'. Let's look at an example to see what is meant by 'non-linear', but first we had better go over some terms. Here it is convenient to use z as the dependent variable for user-defined functions of either one independent variable, z=f(x), or two independent variables, z=f(x,y). A parameter is a user-defined variable that fit will adjust, i.e., an unknown quantity in the function declaration. Linearity/non-linearity refers to the relationship of the dependent variable, z, to the parameters which fit is adjusting, not of z to the independent variables, x and/or y. (To be technical, the second {and higher} derivatives of the fitting function with respect to the parameters are zero for a linear least-squares problem).

For linear least-squares (LLS), the user-defined function will be a sum of simple functions, not involving any parameters, each multiplied by one parameter. NLLS handles more complicated functions in which parameters can be used in a large number of ways. An example that illustrates the difference between linear and nonlinear least-squares is the Fourier series. One member may be written as

    z=a*sin(c*x) + b*cos(c*x).
If a and b are the unknown parameters and c is constant, then estimating values of the parameters is a linear least-squares problem. However, if c is an unknown parameter, the problem is nonlinear.

In the linear case, parameter values can be determined by comparatively simple linear algebra, in one direct step. However LLS is a special case which is also solved along with more general NLLS problems by the iterative procedure that gnuplot uses. fit attempts to find the minimum by doing a search. Each step (iteration) calculates WSSR with a new set of parameter values. The Marquardt-Levenberg algorithm selects the parameter values for the next iteration. The process continues until a preset criterion is met, either (1) the fit has "converged" (the relative change in WSSR is less than FIT_LIMIT), or (2) it reaches a preset iteration count limit, FIT_MAXITER (see fit control variables (p. 85)). The fit may also be interrupted and subsequently halted from the keyboard (see fit (p. 79)). The user variable FIT_CONVERGED contains 1 if the previous fit command terminated due to convergence; it contains 0 if the previous fit terminated for any other reason.

Often the function to be fitted will be based on a model (or theory) that attempts to describe or predict the behaviour of the data. Then fit can be used to find values for the free parameters of the model, to determine how well the data fits the model, and to estimate an error range for each parameter. See fit error_estimates (p. 83).

Alternatively, in curve-fitting, functions are selected independent of a model (on the basis of experience as to which are likely to describe the trend of the data with the desired resolution and a minimum number of parameters*functions.) The fit solution then provides an analytic representation of the curve.

However, if all you really want is a smooth curve through your data points, the smooth option to plot may be what you've been looking for rather than fit.

Error estimates

In fit, the term "error" is used in two different contexts, data error estimates and parameter error estimates.

Data error estimates are used to calculate the relative weight of each data point when determining the weighted sum of squared residuals, WSSR or chisquare. They can affect the parameter estimates, since they determine how much influence the deviation of each data point from the fitted function has on the final values. Some of the fit output information, including the parameter error estimates, is more meaningful if accurate data error estimates have been provided.

The 'statistical overview' describes some of the fit output and gives some background for the 'practical guidelines'.

Statistical overview

The theory of non-linear least-squares (NLLS) is generally described in terms of a normal distribution of errors, that is, the input data is assumed to be a sample from a population having a given mean and a Gaussian (normal) distribution about the mean with a given standard deviation. For a sample of sufficiently large size, and knowing the population standard deviation, one can use the statistics of the chisquare distribution to describe a "goodness of fit" by looking at the variable often called "chisquare". Here, it is sufficient to say that a reduced chisquare (chisquare/degrees of freedom, where degrees of freedom is the number of datapoints less the number of parameters being fitted) of 1.0 is an indication that the weighted sum of squared deviations between the fitted function and the data points is the same as that expected for a random sample from a population characterized by the function with the current value of the parameters and the given standard deviations.

If the standard deviation for the population is not constant, as in counting statistics where variance = counts, then each point should be individually weighted when comparing the observed sum of deviations and the expected sum of deviations.

At the conclusion fit reports 'stdfit', the standard deviation of the fit, which is the rms of the residuals, and the variance of the residuals, also called 'reduced chisquare' when the data points are weighted. The number of degrees of freedom (the number of data points minus the number of fitted parameters) is used in these estimates because the parameters used in calculating the residuals of the datapoints were obtained from the same data. These values are exported to the variables

     FIT_NDF = Number of degrees of freedom
     FIT_WSSR = Weighted sum-of-squares residual
     FIT_STDFIT = sqrt(WSSR/NDF)

To estimate confidence levels for the parameters, one can use the minimum chisquare obtained from the fit and chisquare statistics to determine the value of chisquare corresponding to the desired confidence level, but considerably more calculation is required to determine the combinations of parameters which produce such values.

Rather than determine confidence intervals, fit reports parameter error estimates which are readily obtained from the variance-covariance matrix after the final iteration. By convention, these estimates are called "standard errors" or "asymptotic standard errors", since they are calculated in the same way as the standard errors (standard deviation of each parameter) of a linear least-squares problem, even though the statistical conditions for designating the quantity calculated to be a standard deviation are not generally valid for the NLLS problem. The asymptotic standard errors are generally over-optimistic and should not be used for determining confidence levels, but are useful for qualitative purposes.

The final solution also produces a correlation matrix indicating correlation of parameters in the region of the solution; The main diagonal elements, autocorrelation, are always 1; if all parameters were independent, the off-diagonal elements would be nearly 0. Two variables which completely compensate each other would have an off-diagonal element of unit magnitude, with a sign depending on whether the relation is proportional or inversely proportional. The smaller the magnitudes of the off-diagonal elements, the closer the estimates of the standard deviation of each parameter would be to the asymptotic standard error.

Practical guidelines

If you have a basis for assigning weights to each data point, doing so lets you make use of additional knowledge about your measurements, e.g., take into account that some points may be more reliable than others. That may affect the final values of the parameters.

Weighting the data provides a basis for interpreting the additional fit output after the last iteration. Even if you weight each point equally, estimating an average standard deviation rather than using a weight of 1 makes WSSR a dimensionless variable, as chisquare is by definition.

Each fit iteration will display information which can be used to evaluate the progress of the fit. (An '*' indicates that it did not find a smaller WSSR and is trying again.) The 'sum of squares of residuals', also called 'chisquare', is the WSSR between the data and your fitted function; fit has minimized that. At this stage, with weighted data, chisquare is expected to approach the number of degrees of freedom (data points minus parameters). The WSSR can be used to calculate the reduced chisquare (WSSR/ndf) or stdfit, the standard deviation of the fit, sqrt(WSSR/ndf). Both of these are reported for the final WSSR.

If the data are unweighted, stdfit is the rms value of the deviation of the data from the fitted function, in user units.

If you supplied valid data errors, the number of data points is large enough, and the model is correct, the reduced chisquare should be about unity. (For details, look up the 'chi-squared distribution' in your favourite statistics reference.) If so, there are additional tests, beyond the scope of this overview, for determining how well the model fits the data.

A reduced chisquare much larger than 1.0 may be due to incorrect data error estimates, data errors not normally distributed, systematic measurement errors, 'outliers', or an incorrect model function. A plot of the residuals, e.g., plot 'datafile' using 1:($2-f($1)), may help to show any systematic trends. Plotting both the data points and the function may help to suggest another model.

Similarly, a reduced chisquare less than 1.0 indicates WSSR is less than that expected for a random sample from the function with normally distributed errors. The data error estimates may be too large, the statistical assumptions may not be justified, or the model function may be too general, fitting fluctuations in a particular sample in addition to the underlying trends. In the latter case, a simpler function may be more appropriate.

You'll have to get used to both fit and the kind of problems you apply it to before you can relate the standard errors to some more practical estimates of parameter uncertainties or evaluate the significance of the correlation matrix.

Note that fit, in common with most NLLS implementations, minimizes the weighted sum of squared distances (y-f(x))**2. It does not provide any means to account for "errors" in the values of x, only in y. Also, any "outliers" (data points outside the normal distribution of the model) will have an exaggerated effect on the solution.

Control

There are a number of gnuplot variables that can be defined to affect fit. Those which can be defined once gnuplot is running are listed under 'control_variables' while those defined before starting gnuplot are listed under 'environment_variables'.

Control variables

The default epsilon limit (1e-5) may be changed by declaring a value for

     FIT_LIMIT
When the sum of squared residuals changes between two iteration steps by a factor less than this number (epsilon), the fit is considered to have 'converged'.

The maximum number of iterations may be limited by declaring a value for

     FIT_MAXITER
A value of 0 (or not defining it at all) means that there is no limit.

If you need even more control about the algorithm, and know the Marquardt-Levenberg algorithm well, there are some more variables to influence it. The startup value of lambda is normally calculated automatically from the ML-matrix, but if you want to, you may provide your own one with

     FIT_START_LAMBDA

Specifying FIT_START_LAMBDA as zero or less will re-enable the automatic selection. The variable

     FIT_LAMBDA_FACTOR
gives the factor by which lambda is increased or decreased whenever the chi-squared target function increased or decreased significantly. Setting FIT_LAMBDA_FACTOR to zero re-enables the default factor of 10.0.

Other variables with the FIT_ prefix may be added to fit, so it is safer not to use that prefix for user-defined variables.

The variables FIT_SKIP and FIT_INDEX were used by earlier releases of gnuplot with a 'fit' patch called gnufit and are no longer available. The datafile every modifier provides the functionality of FIT_SKIP. FIT_INDEX was used for multi-branch fitting, but multi-branch fitting of one independent variable is now done as a pseudo-3D fit in which the second independent variable and using are used to specify the branch. See fit multi-branch (p. 86).

Environment variables

The environment variables must be defined before gnuplot is executed; how to do so depends on your operating system.

     FIT_LOG
changes the name (and/or path) of the file to which the fit log will be written from the default of "fit.log" in the working directory. The default value can be overwritten using the command set fit logfile.

     FIT_SCRIPT
specifies a command that may be executed after an user interrupt. The default is replot, but a plot or load

command may be useful to display a plot customized to highlight the progress of the fit.

Multi-branch

In multi-branch fitting, multiple data sets can be simultaneously fit with functions of one independent variable having common parameters by minimizing the total WSSR. The function and parameters (branch) for each data set are selected by using a 'pseudo-variable', e.g., either the dataline number (a 'column' index of -1) or the datafile index (-2), as the second independent variable.

Example: Given two exponential decays of the form, z=f(x), each describing a different data set but having a common decay time, estimate the values of the parameters. If the datafile has the format x:z:s, then

    f(x,y) = (y==0) ? a*exp(-x/tau) : b*exp(-x/tau)
    fit f(x,y) 'datafile' using  1:-2:2:3  via a, b, tau

For a more complicated example, see the file "hexa.fnc" used by the "fit.dem" demo.

Appropriate weighting may be required since unit weights may cause one branch to predominate if there is a difference in the scale of the dependent variable. Fitting each branch separately, using the multi-branch solution as initial values, may give an indication as to the relative effect of each branch on the joint solution.

Starting values

Nonlinear fitting is not guaranteed to converge to the global optimum (the solution with the smallest sum of squared residuals, SSR), and can get stuck at a local minimum. The routine has no way to determine that; it is up to you to judge whether this has happened.

fit may, and often will get "lost" if started far from a solution, where SSR is large and changing slowly as the parameters are varied, or it may reach a numerically unstable region (e.g., too large a number causing a floating point overflow) which results in an "undefined value" message or gnuplot halting.

To improve the chances of finding the global optimum, you should set the starting values at least roughly in the vicinity of the solution, e.g., within an order of magnitude, if possible. The closer your starting values are to the solution, the less chance of stopping at another minimum. One way to find starting values is to plot data and the fitting function on the same graph and change parameter values and replot until reasonable similarity is reached. The same plot is also useful to check whether the fit stopped at a minimum with a poor fit.

Of course, a reasonably good fit is not proof there is not a "better" fit (in either a statistical sense, characterized by an improved goodness-of-fit criterion, or a physical sense, with a solution more consistent with the model.) Depending on the problem, it may be desirable to fit with various sets of starting values, covering a reasonable range for each parameter.

Tips

Here are some tips to keep in mind to get the most out of fit. They're not very organized, so you'll have to read them several times until their essence has sunk in.

The two forms of the via argument to fit serve two largely distinct purposes. The via "file" form is best used for (possibly unattended) batch operation, where you just supply the startup values in a file and can later use update to copy the results back into another (or the same) parameter file.

The via var1, var2, ... form is best used interactively, where the command history mechanism may be used to edit the list of parameters to be fitted or to supply new startup values for the next try. This is particularly useful for hard problems, where a direct fit to all parameters at once won't work without good starting values. To find such, you can iterate several times, fitting only some of the parameters, until the values are close enough to the goal that the final fit to all parameters at once will work.

Make sure that there is no mutual dependency among parameters of the function you are fitting. For example, don't try to fit a*exp(x+b), because a*exp(x+b)=a*exp(b)*exp(x). Instead, fit either a*exp(x) or exp(x+b).

A technical issue: the parameters must not be too different in magnitude. The larger the ratio of the largest and the smallest absolute parameter values, the slower the fit will converge. If the ratio is close to or above the inverse of the machine floating point precision, it may take next to forever to converge, or refuse to converge at all. You will have to adapt your function to avoid this, e.g., replace 'parameter' by '1e9*parameter' in the function definition, and divide the starting value by 1e9.

If you can write your function as a linear combination of simple functions weighted by the parameters to be fitted, by all means do so. That helps a lot, because the problem is no longer nonlinear and should converge with only a small number of iterations, perhaps just one.

Some prescriptions for analysing data, given in practical experimentation courses, may have you first fit some functions to your data, perhaps in a multi-step process of accounting for several aspects of the underlying theory one by one, and then extract the information you really wanted from the fitting parameters of those functions. With fit, this may often be done in one step by writing the model function directly in terms of the desired parameters. Transforming data can also quite often be avoided, though sometimes at the cost of a more difficult fit problem. If you think this contradicts the previous paragraph about simplifying the fit function, you are correct.

A "singular matrix" message indicates that this implementation of the Marquardt-Levenberg algorithm can't calculate parameter values for the next iteration. Try different starting values, writing the function in another form, or a simpler function.

Finally, a nice quote from the manual of another fitting package (fudgit), that kind of summarizes all these issues: "Nonlinear fitting is an art!"

Help

The help command displays built-in help. To specify information on a particular topic use the syntax:

     help {<topic>}

If <topic> is not specified, a short message is printed about gnuplot. After help for the requested topic is given, a menu of subtopics is given; help for a subtopic may be requested by typing its name, extending the help request. After that subtopic has been printed, the request may be extended again or you may go back one level to the previous topic. Eventually, the gnuplot command line will return.

If a question mark (?) is given as the topic, the list of topics currently available is printed on the screen.

History

history command lists or saves previous entries in the history of the command line editing, or executes an entry.

Here you find 'usage by examples':

     history               # show the complete history
     history 5             # show last 5 entries in the history
     history quiet 5       # show last 5 entries without entry numbers
     history "hist.gp"     # write the complete history to file hist.gp
     history "hist.gp" append # append the complete history to file hist.gp
     history 10 "hist.gp"  # write last 10 commands to file hist.gp
     history 10 "|head -5 >>diary.gp" # write 5 history commands using pipe
     history ?load         # show all history entries starting with "load"
     history ?"set c"      # like above, several words enclosed in quotes
     hi !reread            # execute last entry starting with "reread"
     hist !"set xr"        # like above, several words enclosed in quotes
     hi !hi                # guess yourself :-))

On systems which support a popen function (Unix), the output of history can be piped through an external program by starting the file name with a '|', as one of the above examples demonstrates.

If

New syntax:

     if (<condition>) { <command>; <command>
            <commands>
            <commands>
     } else {
            <commands>
     }
Old syntax:
     if (<condition>) <command-line> [; else if (<condition>) ...; else ...]

This version of gnuplot supports block-structured if/else statements. If the keyword if or else is immediately followed by an opening "{", then conditional execution applies to all statements, possibly on multiple input lines, until a matching "}" terminates the block. If commands may be nested.

The old single-line if/else syntax is still supported, but can not be mixed with the new block-structured syntax. See if-old (p. 89).

If-old

Through gnuplot version 4.4, the scope of the if/else commands was limited to a single input line. This has been replaced by allowing a multi-line clause to be enclosed in curly brackets. The old syntax is still honored by itself but cannot be used inside a bracketed clause.

If no opening "{" follows the if keyword, the command(s) in <command-line> will be executed if <condition> is true (non-zero) or skipped if <condition> is false (zero). Either case will consume commands on the input line until the end of the line or an occurrence of else. Note that use of ; to allow multiple commands on the same line will not end the conditionalized commands.

Examples:

     pi=3
     if (pi!=acos(-1)) print "?Fixing pi!"; pi=acos(-1); print pi

will display:

     ?Fixing pi!
     3.14159265358979

but

     if (1==2) print "Never see this"; print "Or this either"
will not display anything.

else:

     v=0
     v=v+1; if (v%2) print "2" ; else if (v%3) print "3"; else print "fred"
(repeat the last line repeatedly!)

See reread (p. 125) for an example of using if and reread together to perform a loop.

Iteration

The plot, splot, set and unset commands may optionally contain an iteration clause. This has the effect of executing the basic command multiple times, each time re-evaluating any expressions that make use of the iteration control variable. Iteration of arbitrary command sequences can be requested using the do command. Two forms of iteration clause are currently supported:

     for [intvar = start:end{:increment}]
     for [stringvar in "A B C D"]

Examples:

     plot for [filename in "A.dat B.dat C.dat"] filename using 1:2 with lines
     plot for [basename in "A B C"] basename.".dat" using 1:2 with lines
     set for [i = 1:10] style line i lc rgb "blue"
     unset for [tag = 100:200] label tag

Nested iteration is supported:

     set for [i=1:9] for [j=1:9] label i*10+j sprintf("%d",i*10+j) at i,j

See additional documentation for plot iteration (p. 117), do (p. 78).

Load

The load command executes each line of the specified input file as if it had been typed in interactively. Files created by the save command can later be loaded. Any text file containing valid commands can be created and then executed by the load command. Files being loaded may themselves contain load or call commands. See comments (p. 24) for information about comments in commands. To load with arguments, see call (p. 77).

Syntax:

     load "<input-file>"

The name of the input file must be enclosed in quotes.

The special filename "-" may be used to load commands from standard input. This allows a gnuplot command file to accept some commands from standard input. Please see help for batch/interactive (p. 22) for more details.

On some systems which support a popen function (Unix), the load file can be read from a pipe by starting the file name with a '<'.

Examples:

     load 'work.gnu'
     load "func.dat"
     load "< loadfile_generator.sh"

The load command is performed implicitly on any file names given as arguments to gnuplot. These are loaded in the order specified, and then gnuplot exits.

Lower

Syntax:

     lower {plot_window_nb}

The lower command lowers (opposite to raise) plot window(s) associated with the interactive terminal of your gnuplot session, i.e. pm, win, wxt or x11. It puts the plot window to bottom in the z-order windows stack of the window manager of your desktop.

As x11 and wxt support multiple plot windows, then by default they lower these windows in descending order of most recently created on top to the least recently created on bottom. If a plot number is supplied as an optional parameter, only the associated plot window will be lowered if it exists.

The optional parameter is ignored for single plot-window terminals, i.e. pm and win.

Pause

The pause command displays any text associated with the command and then waits a specified amount of time or until the carriage return is pressed. pause is especially useful in conjunction with load files.

Syntax:

     pause <time> {"<string>"}
     pause mouse {<endcondition>}{, <endcondition>} {"<string>"}

<time> may be any constant or expression. Choosing -1 will wait until a carriage return is hit, zero (0) won't pause at all, and a positive number will wait the specified number of seconds. The time is rounded to an integer number of seconds if subsecond time resolution is not supported by the given platform. pause 0 is synonymous with print.

If the current terminal supports mousing, then pause mouse will terminate on either a mouse click or on ctrl-C. For all other terminals, or if mousing is not active, pause mouse is equivalent to pause -1.

If one or more end conditions are given after pause mouse, then any one of the conditions will terminate the pause. The possible end conditions are keypress, button1, button2, button3, close, and any. If the pause terminates on a keypress, then the ascii value of the key pressed is returned in MOUSE_KEY. The character itself is returned as a one character string in MOUSE_CHAR. Hotkeys (bind command) are disabled if keypress is one of the end conditions. Zooming is disabled if button3 is one of the end conditions.

In all cases the coordinates of the mouse are returned in variables MOUSE_X, MOUSE_Y, MOUSE_X2, MOUSE_Y2. See mouse variables (p. 45).

Note: Since pause communicates with the operating system rather than the graphics, it may behave differently with different device drivers (depending upon how text and graphics are mixed).

Examples:

     pause -1    # Wait until a carriage return is hit
     pause 3     # Wait three seconds
     pause -1  "Hit return to continue"
     pause 10  "Isn't this pretty?  It's a cubic spline."
     pause mouse "Click any mouse button on selected data point"
     pause mouse keypress "Type a letter from A-F in the active window"
     pause mouse button1,keypress
     pause mouse any "Any key or button will terminate"

The variant "pause mouse key" will resume after any keypress in the active plot window. If you want to wait for a particular key to be pressed, you can use a reread loop such as:

     print "I will resume after you hit the Tab key in the plot window"
     load "wait_for_tab"

File "wait_for_tab" contains the lines

     pause mouse key
     if (MOUSE_KEY != 9) reread

Plot

plot is the primary command for drawing plots with gnuplot. It creates plots of functions and data in many, many ways. plot is used to draw 2D functions and data; splot draws 2D projections of 3D surfaces and data. plot and splot offer many features in common; see splot (p. 231) for differences. Note specifically that although the binary <binary list> variation does work for both plot and splot, there are small differences between them.

Syntax:

     plot {<ranges>}
          {<iteration>}
          {<function> | {"<datafile>" {datafile-modifiers}}}
          {axes <axes>} {<title-spec>} {with <style>}
          {, {definitions{,}} <function> ...}

where either a <function> or the name of a data file enclosed in quotes is supplied. A function is a mathematical expression or a pair of mathematical expressions in parametric mode. Functions may be builtin, user-defined, or provided in the plot command itself. Multiple datafiles and/or functions may be plotted in a single command, separated by commas. See data (p. 99), functions (p. 115).

Examples:

     plot sin(x)
     plot sin(x), cos(x)
     plot f(x) = sin(x*a), a = .2, f(x), a = .4, f(x)
     plot "datafile.1" with lines, "datafile.2" with points
     plot [t=1:10] [-pi:pi*2] tan(t), \
          "data.1" using (tan($2)):($3/$4) smooth csplines \
                   axes x1y2 notitle with lines 5
     plot for [datafile in "spinach.dat broccoli.dat"] datafile

See also show plot (p. 182).

Axes

There are four possible sets of axes available; the keyword <axes> is used to select the axes for which a particular line should be scaled. x1y1 refers to the axes on the bottom and left; x2y2 to those on the top and right; x1y2 to those on the bottom and right; and x2y1 to those on the top and left. Ranges specified on the plot command apply only to the first set of axes (bottom left).

Binary

BINARY DATA FILES:

Some earlier versions of gnuplot automatically detected binary data files. It is now necessary to provide the keyword binary after the filename. Adequate details of the file format must be given on the command line or extracted from the file itself for a supported binary filetype. In particular, there are two structures for binary files, binary matrix format and binary general format.

The binary matrix format contains a two dimensional array of 32 bit IEEE float values with an additional column and row of coordinate values. As with ASCII matrix, in the using list, enumeration of the coordinate row constitutes column 1, enumeration of the coordinate column constitutes column 2, and the array of values constitutes column 3.

The binary general format contains an arbitrary number of columns for which information must be specified at the command line. For example, array, record, format and using can indicate the size, format and dimension of data. There are a variety of useful commands for skipping file headers and changing endianess. There are a set of commands for positioning and translating data since often coordinates are not part of the file when uniform sampling is inherent in the data. Different from matrix binary or ASCII, general binary does not treat the generated columns as 1, 2 or 3 in the using list. Rather, column 1 begins with column 1 of the file, or as specified in the format list.

There are global default settings for the various binary options which may be set using the same syntax as the options when used as part of the (s)plot <filename> binary ... command. This syntax is set datafile binary .... The general rule is that common command-line specified parameters override file-extracted parameters which override default parameters.

Binary matrix is the default binary format when no keywords specific to binary general are given, i.e., array, record, format, filetype.

General binary data can be entered at the command line via the special file name '-'. However, this is intended for use through a pipe where programs can exchange binary data, not for keyboards. There is no "end of record" character for binary data. Gnuplot continues reading from a pipe until it has read the number of points declared in the array qualifier. See binary matrix (p. 232) or binary general (p. 94) for more details.

The index keyword is not supported, since the file format allows only one surface per file. The every and using filters are supported. using operates as if the data were read in the above triplet form.

Binary File Splot Demo.

General

General binary data in which format information is not necessarily part of the file can be read by giving further details about the file format at the command line. Although the syntax is slightly arcane to the casual user, general binary is particularly useful for application programs using gnuplot and sending large amounts of data.

Syntax:

     plot '<file_name>' {binary <binary list>} ...
     splot '<file_name>' {binary <binary list>} ...

General binary format is activated by keywords in <binary list> pertaining to information about file structure, i.e., array, record, format or filetype. Otherwise, matrix binary format is assumed. (See binary matrix (p. 232) for more details.)

There are some standard file types that may be read for which details about the binary format may be extracted automatically. (Type show datafile binary at the command line for a list.) Otherwise, details must be specified at the command line or set in the defaults. Keywords are described below.

The keyword filetype in <binary list> controls the routine used to read the file, i.e., the format of the data. For a list of the supported file types, type show datafile binary filetypes. If no file type is given, the rule is that traditional gnuplot binary is assumed for splot if the binary keyword stands alone. In all other circumstances, for plot or when one of the <binary list> keywords appears, a raw binary file is assumed whereby the keywords specify the binary format.

General binary data files fall into two basic classes, and some files may be of both classes depending upon how they are treated. There is that class for which uniform sampling is assumed and point coordinates must be generated. This is the class for which full control via the <binary list> keywords applies. For this class, the settings precedence is that command line parameters override in-file parameters, which override default settings. The other class is that set of files for which coordinate information is contained within the file or there is possibly a non-uniform sampling such as gnuplot binary.

Other than for the unique data files such as gnuplot binary, one should think of binary data as conceptually the same as ASCII data. Each point has columns of information which are selected via the <using list> associated with using. When no format string is specified, gnuplot will retrieve a number of binary variables equal to the largest column given in the <using list>. For example, using 1:3 will result in three columns being read, of which the second will be ignored. There are default using lists based upon the typical number of parameters associated with a certain plot type. For example, with image has a default of using 1, while with rgbimage has a default of using 1:2:3. Note that the special characters for using representing point/line/index generally should not be used for binary data. There are keywords in <binary list> that control this.

Array

Describes the sampling array dimensions associated with the binary file. The coordinates will be generated by gnuplot. A number must be specified for each dimension of the array. For example, array=(10,20) means the underlying sampling structure is two-dimensional with 10 points along the first (x) dimension and 20 points along the second (y) dimension. A negative number indicates that data should be read until the end of file. If there is only one dimension, the parentheses may be omitted. A colon can be used to separate the dimensions for multiple records. For example, array=25:35 indicates there are two one-dimensional records in the file.

     Note:  Gnuplot version 4.2 used the syntax array=128x128 rather than
            array=(128,128). The older syntax is now deprecated, but may
            still work if your copy of gnuplot was built to support
            backwards compatibility.
Record

This keyword serves the same function as array, having the same syntax. However, record causes gnuplot to not generate coordinate information. This is for the case where such information may be included in one of the columns of the binary data file.

Skip

This keyword allows you to skip sections of a binary file. For instance, if the file contains a 1024 byte header before the start of the data region you would probably want to use

     plot '<file_name>' binary skip=1024 ...
If there are multiple records in the file, you may specify a leading offset for each. For example, to skip 512 bytes before the 1st record and 256 bytes before the second and third records
     plot '<file_name> binary record=356:356:356 skip=512:256:256 ...
Format

The default binary format is a float. For more flexibility, the format can include details about variable sizes. For example, format="%uchar%int%float" associates an unsigned character with the first using column, an int with the second column and a float with the third column. If the number of size specifications is less than the greatest column number, the size is implicitly taken to be similar to the last given variable size.

Furthermore, similar to the using specification, the format can include discarded columns via the * character and have implicit repetition via a numerical repeat-field. For example, format="%*2int%3float" causes gnuplot to discard two ints before reading three floats. To list variable sizes, type show datafile binary datasizes. There are a group of names that are machine dependent along with their sizes in bytes for the particular compilation. There is also a group of names which attempt to be machine independent.

Endian

Often the endianess of binary data in the file does not agree with the endianess used by the platform on which gnuplot is running. Several words can direct gnuplot how to arrange bytes. For example endian=little means treat the binary file as having byte significance from least to greatest. The options are

             little:  least significant to greatest significance
                big:  greatest significance to least significance
            default:  assume file endianess is the same as compiler
        swap (swab):  Interchange the significance.  (If things
                      don't look right, try this.)

Gnuplot can support "middle" ("pdp") endian if it is compiled with that option.

Filetype

For some standard binary file formats gnuplot can extract all the necessary information from the file in question. As an example, "format=edf" will read ESRF Header File format files. For a list of the currently supported file formats, type show datafile binary filetypes.

There is a special file type called auto for which gnuplot will check if the binary file's extension is a quasi-standard extension for a supported format.

Command line keywords may be used to override settings extracted from the file. The settings from the file override any defaults. (See set datafile binary (p. 146) for details.)

Avs avs is one of the automatically recognized binary file types for images. AVS is an extremely simple format, suitable mostly for streaming between applications. It consists of 2 longs (xwidth, ywidth) followed by a stream of pixels, each with four bytes of information alpha/red/green/blue.

Edf edf is one of the automatically recognized binary file types for images. EDF stands for ESRF Data Format, and it supports both edf and ehf formats (the latter means ESRF Header Format). More information on specifications can be found at

 http://www.edfplus.info/specs

Png If gnuplot was configured to use the libgd library for png/gif/jpeg output, then it can also be used to read these same image types as binary files. You can use an explicit command

     plot 'file.png' binary filetype=png

Or the file type will be recognized automatically from the extension if you have previously requested

     set datafile binary filetype=auto
Keywords

The following keywords apply only when generating coordinates from binary data files. That is, the control mapping the individual elements of a binary array, matrix, or image to specific x/y/z positions.

Scan A great deal of confusion can arise concerning the relationship between how gnuplot scans a binary file and the dimensions seen on the plot. To lessen the confusion, conceptually think of gnuplot always scanning the binary file point/line/plane or fast/medium/slow. Then this keyword is used to tell gnuplot how to map this scanning convention to the Cartesian convention shown in plots, i.e., x/y/z. The qualifier for scan is a two or three letter code representing where point is assigned (first letter), line is assigned (second letter), and plane is assigned (third letter). For example, scan=yx means the fastest, point-by-point, increment should be mapped along the Cartesian y dimension and the middle, line-by-line, increment should be mapped along the x dimension.

When the plotting mode is plot, the qualifier code can include the two letters x and y. For splot, it can include the three letters x, y and z.

There is nothing restricting the inherent mapping from point/line/plane to apply only to Cartesian coordinates. For this reason there are cylindrical coordinate synonyms for the qualifier codes where t (theta), r and z are analogous to the x, y and z of Cartesian coordinates.

Transpose Shorthand notation for scan=yx or scan=yxz.

Dx, dy, dz When gnuplot generates coordinates, it uses the spacing described by these keywords. For example dx=10 dy=20 would mean space samples along the x dimension by 10 and space samples along the y dimension by 20. dy cannot appear if dx does not appear. Similarly, dz cannot appear if dy does not appear. If the underlying dimensions are greater than the keywords specified, the spacing of the highest dimension given is extended to the other dimensions. For example, if an image is being read from a file and only dx=3.5 is given gnuplot uses a delta x and delta y of 3.5.

The following keywords also apply only when generating coordinates. However they may also be used with matrix binary files.

Flipx, flipy, flipz Sometimes the scanning directions in a binary datafile are not consistent with that assumed by gnuplot. These keywords can flip the scanning direction along dimensions x, y, z.

Origin When gnuplot generates coordinates based upon transposition and flip, it attempts to always position the lower left point in the array at the origin, i.e., the data lies in the first quadrant of a Cartesian system after transpose and flip.

To position the array somewhere else on the graph, the origin keyword directs gnuplot to position the lower left point of the array at a point specified by a tuple. The tuple should be a double for plot and a triple for splot. For example, origin=(100,100):(100,200) is for two records in the file and intended for plotting in two dimensions. A second example, origin=(0,0,3.5), is for plotting in three dimensions.

Center Similar to origin, this keyword will position the array such that its center lies at the point given by the tuple. For example, center=(0,0). Center does not apply when the size of the array is Inf.

Rotate The transpose and flip commands provide some flexibility in generating and orienting coordinates. However, for full degrees of freedom, it is possible to apply a rotational vector described by a rotational angle in two dimensions.

The rotate keyword applies to the two-dimensional plane, whether it be plot or splot. The rotation is done with respect to the positive angle of the Cartesian plane.

The angle can be expressed in radians, radians as a multiple of pi, or degrees. For example, rotate=1.5708, rotate=0.5pi and rotate=90deg are equivalent.

If origin is specified, the rotation is done about the lower left sample point before translation. Otherwise, the rotation is done about the array center.

Perpendicular For splot, the concept of a rotational vector is implemented by a triple representing the vector to be oriented normal to the two-dimensional x-y plane. Naturally, the default is (0,0,1). Thus specifying both rotate and perpendicular together can orient data myriad ways in three-space.

The two-dimensional rotation is done first, followed by the three-dimensional rotation. That is, if R' is the rotational 2 x 2 matrix described by an angle, and P is the 3 x 3 matrix projecting (0,0,1) to (xp,yp,zp), let R be constructed from R' at the upper left sub-matrix, 1 at element 3,3 and zeros elsewhere. Then the matrix formula for translating data is v' = P R v, where v is the 3 x 1 vector of data extracted from the data file. In cases where the data of the file is inherently not three-dimensional, logical rules are used to place the data in three-space. (E.g., usually setting the z-dimension value to zero and placing 2D data in the x-y plane.)

Data

Discrete data contained in a file can be displayed by specifying the name of the data file (enclosed in single or double quotes) on the plot command line.

Syntax:

     plot '<file_name>' {binary <binary list>}
                        {{nonuniform} matrix}
                        {index <index list> | index "<name>"}
                        {every <every list>}
                        {thru <thru expression>}
                        {using <using list>}
                        {smooth <option>}
                        {volatile} {noautoscale}

The modifiers binary, index, every, thru, using, and smooth are discussed separately. In brief, binary allows data entry from a binary file (default is ASCII), index selects which data sets in a multi-data-set file are to be plotted, every specifies which points within a single data set are to be plotted, using determines how the columns within a single record are to be interpreted (thru is a special case of using), and smooth allows for simple interpolation and approximation. (splot has a similar syntax, but does not support the smooth and thru options.)

The noautoscale keyword means that the points making up this plot will be ignored when automatically determining axis range limits.

ASCII DATA FILES:

Data files should contain at least one data point per record (using can select one data point from the record). Records beginning with # (and also with ! on VMS) will be treated as comments and ignored. Each data point represents an (x,y) pair. For plots with error bars or error bars with lines (see set style errorbars (p. 73) or set style errorlines (p. 75)), each data point is (x,y,ydelta), (x,y,ylow,yhigh), (x,y,xdelta), (x,y,xlow,xhigh), or (x,y,xlow,xhigh,ylow,yhigh).

In all cases, the numbers of each record of a data file must be separated by white space (one or more blanks or tabs) unless a format specifier is provided by the using option. This white space divides each record into columns. However, whitespace inside a pair of double quotes is ignored when counting columns, so the following datafile line has three columns:

     1.0 "second column" 3.0

Data may be written in exponential format with the exponent preceded by the letter e or E. The fortran exponential specifiers d, D, q, and Q may also be used if the command set datafile fortran is in effect.

Only one column (the y value) need be provided. If x is omitted, gnuplot provides integer values starting at 0.

In datafiles, blank records (records with no characters other than blanks and a newline and/or carriage return) are significant.

Single blank records designate discontinuities in a plot; no line will join points separated by a blank records (if they are plotted with a line style).

Two blank records in a row indicate a break between separate data sets. See index (p. 103).

If autoscaling has been enabled (set autoscale), the axes are automatically extended to include all datapoints, with a whole number of tic marks if tics are being drawn. This has two consequences: i) For splot, the corner of the surface may not coincide with the corner of the base. In this case, no vertical line is drawn. ii) When plotting data with the same x range on a dual-axis graph, the x coordinates may not coincide if the x2tics are not being drawn. This is because the x axis has been autoextended to a whole number of tics, but the x2 axis has not. The following example illustrates the problem:

     reset; plot '-', '-' axes x2y1
     1 1
     19 19
     e
     1 1
     19 19
     e

To avoid this, you can use the fixmin/fixmax feature of the set autoscale command, which turns off the automatic extension of the axis range up to the next tic mark.

Label coordinates and text can also be read from a data file (see labels (p. 69)).

Every

The every keyword allows a periodic sampling of a data set to be plotted.

In the discussion a "point" is a datum defined by a single record in the file; "block" here will mean the same thing as "datablock" (see glossary (p. 39)).

Syntax:

     plot 'file' every {<point_incr>}
                         {:{<block_incr>}
                           {:{<start_point>}
                             {:{<start_block>}
                               {:{<end_point>}
                                 {:<end_block>}}}}}

The data points to be plotted are selected according to a loop from <start_point> to <end_point> with increment <point_incr> and the blocks according to a loop from <start_block> to <end_block> with increment <block_incr>.

The first datum in each block is numbered '0', as is the first block in the file.

Note that records containing unplottable information are counted.

Any of the numbers can be omitted; the increments default to unity, the start values to the first point or block, and the end values to the last point or block. If every is not specified, all points in all lines are plotted.

Examples:

     every :::3::3    # selects just the fourth block ('0' is first)
     every :::::9     # selects the first 10 blocks
     every 2:2        # selects every other point in every other block
     every ::5::15    # selects points 5 through 15 in each block

See simple plot demos (simple.dem), Non-parametric splot demos, and Parametric splot demos.

Example datafile

This example plots the data in the file "population.dat" and a theoretical curve:

     pop(x) = 103*exp((1965-x)/10)
     set xrange [1960:1990]
     plot 'population.dat', pop(x)

The file "population.dat" might contain:

     # Gnu population in Antarctica since 1965
        1965   103
        1970   55
        1975   34
        1980   24
        1985   10

Binary examples:

     # Selects two float values (second one implicit) with a float value
     # discarded between them for an indefinite length of 1D data.
     plot '<file_name>' binary format="%float%*float" using 1:2 with lines

     # The data file header contains all details necessary for creating
     # coordinates from an EDF file.
     plot '<file_name>' binary filetype=edf with image
     plot '<file_name>.edf' binary filetype=auto with image

     # Selects three unsigned characters for components of a raw RGB image
     # and flips the y-dimension so that typical image orientation (start
     # at top left corner) translates to the Cartesian plane.  Pixel
     # spacing is given and there are two images in the file.  One of them
     # is translated via origin.
     plot '<file_name>' binary array=(512,1024):(1024,512) format='%uchar' \
          dx=2:1 dy=1:2 origin=(0,0):(1024,1024) flipy u 1:2:3 w rgbimage

     # Four separate records in which the coordinates are part of the
     # data file.  The file was created with a endianess different from
     # the system on which gnuplot is running.
     splot '<file_name>' binary record=30:30:29:26 endian=swap u 1:2:3

     # Same input file, but this time we skip the 1st and 3rd records
     splot '<file_name>' binary record=30:26 skip=360:348 endian=swap u 1:2:3

See also binary matrix (p. 232).

Index

The index keyword allows you to select specific data sets in a multi-data-set file for plotting.

Syntax:

     plot 'file' index { <m>{:<n>{:<p>}} | "<name>" }

Data sets are separated by pairs of blank records. index <m> selects only set <m>; index <m>:<n> selects sets in the range <m> to <n>; and index <m>:<n>:<p> selects indices <m>, <m>+<p>, <m>+2<p>, etc., but stopping at <n>. Following C indexing, the index 0 is assigned to the first data set in the file. Specifying too large an index results in an error message. If <p> is specified but <n> is left blank then every <p>-th dataset is read until the end of the file. If index is not specified, the entire file is plotted as a single data set.

Example:

     plot 'file' index 4:5

For each point in the file, the index value of the data set it appears in is available via the pseudo-column column(-2). This leads to an alternative way of distinguishing individual data sets within a file as shown below. This is more awkward than the index command if all you are doing is selecting one data set for plotting, but is very useful if you want to assign different properties to each data set. See pseudocolumns (p. 111), lc variable (p. 42).

Example:

     plot 'file' using 1:(column(-2)==4 ? $2 : NaN)        # very awkward
     plot 'file' using 1:2:(column(-2)) linecolor variable # very useful!

index '<name>' selects the data set with name '<name>'. Names are assigned to data sets in comment lines. The comment character and leading white space are removed from the comment line. If the resulting line starts with <name>, the following data set is now named <name> and can be selected.

Example:

     plot 'file' index 'Population'

Please note that every comment that starts with <name> will name the following data set. To avoid problems it may be useful to choose a naming scheme like '== Population ==' or '[Population]'.

Smooth

gnuplot includes a few general-purpose routines for interpolation and approximation of data; these are grouped under the smooth option. More sophisticated data processing may be performed by preprocessing the data externally or by using fit with an appropriate model.

Syntax:

     smooth {unique | frequency | cumulative | cnormal | kdensity
                    | csplines | acsplines | bezier | sbezier}

unique, frequency, cumulative and cnormal plot the data after making them monotonic. Each of the other routines uses the data to determine the coefficients of a continuous curve between the endpoints of the data. This curve is then plotted in the same manner as a function, that is, by finding its value at uniform intervals along the abscissa (see set samples (p. 197)) and connecting these points with straight line segments (if a line style is chosen).

If autoscale is in effect, the ranges will be computed such that the plotted curve lies within the borders of the graph.

If autoscale is not in effect, and the smooth option is either acspline or cspline, the sampling of the generated curve is done across the intersection of the x range covered by the input data and the fixed abscissa range as defined by set xrange.

If too few points are available to allow the selected option to be applied, an error message is produced. The minimum number is one for unique and frequency, four for acsplines, and three for the others.

The smooth options have no effect on function plots.

Acsplines The acsplines option approximates the data with a "natural smoothing spline". After the data are made monotonic in x (see smooth unique (p. 105)), a curve is piecewise constructed from segments of cubic polynomials whose coefficients are found by the weighting the data points; the weights are taken from the third column in the data file. That default can be modified by the third entry in the using list, e.g.,

     plot 'data-file' using 1:2:(1.0) smooth acsplines

Qualitatively, the absolute magnitude of the weights determines the number of segments used to construct the curve. If the weights are large, the effect of each datum is large and the curve approaches that produced by connecting consecutive points with natural cubic splines. If the weights are small, the curve is composed of fewer segments and thus is smoother; the limiting case is the single segment produced by a weighted linear least squares fit to all the data. The smoothing weight can be expressed in terms of errors as a statistical weight for a point divided by a "smoothing factor" for the curve so that (standard) errors in the file can be used as smoothing weights.

Example:

     sw(x,S)=1/(x*x*S)
     plot 'data_file' using 1:2:(sw($3,100)) smooth acsplines

Bezier The bezier option approximates the data with a Bezier curve of degree n (the number of data points) that connects the endpoints.

Csplines The csplines option connects consecutive points by natural cubic splines after rendering the data monotonic (see smooth unique (p. 105)).

Sbezier The sbezier option first renders the data monotonic (unique) and then applies the bezier algorithm.

Unique The unique option makes the data monotonic in x; points with the same x-value are replaced by a single point having the average y-value. The resulting points are then connected by straight line segments.

Frequency The frequency option makes the data monotonic in x; points with the same x-value are replaced by a single point having the summed y-values. The resulting points are then connected by straight line segments. See also smooth.dem

Cumulative The cumulative option makes the data monotonic in x; points with the same x-value are replaced by a single point containing the cumulative sum of y-values of all data points with lower x-values (i.e. to the left of the current data point). This can be used to obtain a cumulative distribution function from data. See also smooth.dem

Cnormal The cnormal option makes the data monotonic in x and normalises the y-values onto the range [0:1]. Points with the same x-value are replaced by a single point containing the cumulative sum of y-values of all data points with lower x-values (i.e. to the left of the current data point) divided by the total sum of all y-values. This can be used to obtain a normalised cumulative distribution function from data (useful when comparing sets of samples with differing numbers of members). See also smooth.dem

Kdensity The kdensity option is a way to plot a kernel density estimate (which is a smooth histogram) for a random collection of points, using Gaussian kernels. A Gaussian is placed at the location of each point in the first column and the sum of all these Gaussians is plotted as a function. The value in the second column is taken as weight of the Gaussian. (To obtain a normalized histogram, this should be 1/number-of-points). The value of the third column, if supplied, is taken as the bandwidth for the kernels. If only two columns have been specified, or if the value of the third column is zero or less, gnuplot calculates the bandwidth which would be optimal if the input data was normally distributed. (This will usually be a very conservative, i.e. broad bandwidth.)

Special-filenames

There are a few filenames that have a special meaning: ' ', '-', '+' and '++'.

The empty filename ' ' tells gnuplot to re-use the previous input file in the same plot command. So to plot two columns from the same input file:

     plot 'filename' using 1:2, '' using 1:3

The special filenames '+' and '++' are a mechanism to allow the full range of using specifiers and plot styles with in-line functions. Normally a function plot can only have a single y (or z) value associated with each sampled point. The pseudo-file '+' treats the sampled points as column 1, and allows additional column values to be specified via a using specification, just as for a true input file. The number of samples returned is controlled by set samples. Example:

     plot '+' using ($1):(sin($1)):(sin($1)**2) with filledcurves

Similarly the pseudo-file '++' returns 2 columns of data forming a regular grid of [x,y] coordinates with the number of points along x controlled by set samples and the number of points along y controlled by set isosamples. You must set xrange and yrange before plotting '++'. Examples:

     splot '++' using 1:2:(sin($1)*sin($2)) with pm3d
     plot '++' using 1:2:(sin($1)*sin($2)) with image

The special filename '-' specifies that the data are inline; i.e., they follow the command. Only the data follow the command; plot options like filters, titles, and line styles remain on the plot command line. This is similar to << in unix shell script, and $DECK in VMS DCL. The data are entered as though they are being read from a file, one data point per record. The letter "e" at the start of the first column terminates data entry. The using option can be applied to these data — using it to filter them through a function might make sense, but selecting columns probably doesn't!

'-' is intended for situations where it is useful to have data and commands together, e.g., when gnuplot is run as a sub-process of some front-end application. Some of the demos, for example, might use this feature. While plot options such as index and every are recognized, their use forces you to enter data that won't be used. For example, while

     plot '-' index 0, '-' index 1
     2
     4
     6


     10
     12
     14
     e
     2
     4
     6
                                                                                         
                                                                                         
     10
     12
     14
     e

does indeed work,

     plot '-', '-'
     2
     4
     6
     e
     10
     12
     14
     e

is a lot easier to type.

If you use '-' with replot, you may need to enter the data more than once. See replot (p. 125), refresh (p. 124).

A blank filename (' ') specifies that the previous filename should be reused. This can be useful with things like

     plot 'a/very/long/filename' using 1:2, '' using 1:3, '' using 1:4

(If you use both '-' and ' ' on the same plot command, you'll need to have two sets of inline data, as in the example above.)

On systems with a popen function, the datafile can be piped through a shell command by starting the file name with a '<'. For example,

     pop(x) = 103*exp(-x/10)
     plot "< awk '{print $1-1965, $2}' population.dat", pop(x)

would plot the same information as the first population example but with years since 1965 as the x axis. If you want to execute this example, you have to delete all comments from the data file above or substitute the following command for the first part of the command above (the part up to the comma):

     plot "< awk '$0 !~ /^#/ {print $1-1965, $2}' population.dat"

While this approach is most flexible, it is possible to achieve simple filtering with the using or thru keywords.

Thru

The thru function is provided for backward compatibility.

Syntax:

     plot 'file' thru f(x)

It is equivalent to:

     plot 'file' using 1:(f($2))

While the latter appears more complex, it is much more flexible. The more natural

     plot 'file' thru f(y)

also works (i.e. you can use y as the dummy variable).

thru is parsed for splot and fit but has no effect.

Using

The most common datafile modifier is using. It tells the program which columns of data in the input file are to be plotted.

Syntax:

     plot 'file' using <entry> {:<entry> {:<entry> ...}} {'format'}

If a format is specified, it is used to read in each datafile record using the C library 'scanf' function. Otherwise the record is interpreted as consisting of columns (fields) of data separated by whitespace (spaces and/or tabs), but see datafile separator (p. 144).

Each <entry> may be a simple column number that selects the value from one field of the input file, a string that matches a column label in the first line of a data set, an expression enclosed in parentheses, or a special function not enclosed in parentheses such as xticlabels(2).

If the entry is an expression in parentheses, then the function column(N) may be used to indicate the value in column N. That is, column(1) refers to the first item read, column(2) to the second, and so on. The special symbols $1, $2, ... are shorthand for column(1), column(2) ... The function valid(N) tests whether the value in the Nth column is a valid number. If each column of data in the input file contains a label in the first row rather than a data value, this label can be used to identify the column on input and/or in the plot legend. The column() function can be used to select an input column by label rather than by column number. For example, if the data file contains

     Height    Weight    Age
     val1      val1      val1
     ...       ...       ...

then the following plot commands are all equivalent

     plot 'datafile' using 3:1, '' using 3:2
     plot 'datafile' using (column("Age")):(column(1)), \
                  '' using (column("Age")):(column(2))
     plot 'datafile' using "Age":"Height", '' using "Age":"Weight"

To use the column labels in the plot legend, use set key autotitle columnhead.

In addition to the actual columns 1...N in the input data file, gnuplot presents data from several "pseudo-columns" that hold bookkeeping information. E.g. $0 or column(0) returns the sequence number of this data record within a dataset. Please see pseudocolumns (p. 111).

An empty <entry> will default to its order in the list of entries. For example, using ::4 is interpreted as using 1:2:4.

If the using list has only a single entry, that <entry> will be used for y and the data point number (pseudo-column $0) is used for x; for example, "plot 'file' using 1" is identical to "plot 'file' using 0:1". If the using list has two entries, these will be used for x and y. See set style (p. 198) and fit (p. 79) for details about plotting styles that make use of data from additional columns of input.

'scanf' accepts several numerical specifications but gnuplot requires all inputs to be double-precision floating-point variables, so "%lf" is essentially the only permissible specifier. A format string given by the user must contain at least one such input specifier, and no more than seven of them. 'scanf' expects to see white space — a blank, tab ("\t"), newline ("\n"), or formfeed ("\f") — between numbers; anything else in the input stream must be explicitly skipped.

Note that the use of "\t", "\n", or "\f" requires use of double-quotes rather than single-quotes.

Using_examples This creates a plot of the sum of the 2nd and 3rd data against the first: The format string specifies comma- rather than space-separated columns. The same result could be achieved by specifying set datafile separator ",".

     plot 'file' using 1:($2+$3) '%lf,%lf,%lf'

In this example the data are read from the file "MyData" using a more complicated format:

     plot 'MyData' using "%*lf%lf%*20[^\n]%lf"

The meaning of this format is:

     %*lf        ignore a number
     %lf         read a double-precision number (x by default)
     %*20[^\n]   ignore 20 non-newline characters
     %lf         read a double-precision number (y by default)

One trick is to use the ternary ?: operator to filter data:

     plot 'file' using 1:($3>10 ? $2 : 1/0)

which plots the datum in column two against that in column one provided the datum in column three exceeds ten. 1/0 is undefined; gnuplot quietly ignores undefined points, so unsuitable points are suppressed. Or you can use the pre-defined variable NaN to achieve the same result.

In fact, you can use a constant expression for the column number, provided it doesn't start with an opening parenthesis; constructs like using 0+(complicated expression) can be used. The crucial point is that the expression is evaluated once if it doesn't start with a left parenthesis, or once for each data point read if it does.

If timeseries data are being used, the time can span multiple columns. The starting column should be specified. Note that the spaces within the time must be included when calculating starting columns for other data. E.g., if the first element on a line is a time with an embedded space, the y value should be specified as column three.

It should be noted that plot 'file', plot 'file' using 1:2, and plot 'file' using ($1):($2) can be subtly different: 1) if file has some lines with one column and some with two, the first will invent x values when they are missing, the second will quietly ignore the lines with one column, and the third will store an undefined value for lines with one point (so that in a plot with lines, no line joins points across the bad point); 2) if a line contains text at the first column, the first will abort the plot on an error, but the second and third should quietly skip the garbage.

In fact, it is often possible to plot a file with lots of lines of garbage at the top simply by specifying

     plot 'file' using 1:2

However, if you want to leave text in your data files, it is safer to put the comment character (#) in the first column of the text lines.

Pseudocolumns Expressions in the using clause of a plot statement can refer to additional bookkeeping values in addition to the actual data values contained in the input file. These are contained in "pseudocolumns".

     column(0)   The sequential order of each point within a data set.
                 The counter starts at 0 and is reset by two sequential blank
                 records.  The shorthand form $0 is available.
     column(-1)  This counter starts at 0 and is reset by a single blank line.
                 This corresponds to the data line in array or grid data.
     column(-2)  The index number of the current data set within a file that
                 contains multiple data sets.  See ‘index‘.

Xticlabels Axis tick labels can be generated via a string function, usually taking a data column as an argument. The simplest form uses the data column itself as a string. That is, xticlabels(N) is shorthand for xticlabels(stringcolumn(N)). This example uses the contents of column 3 as x-axis tick labels.

     plot 'datafile' using <xcol>:<ycol>:xticlabels(3) with <plotstyle>

Axis tick labels may be generated for any of the plot axes: x x2 y y2 z. The ticlabels(<labelcol>) specifiers must come after all of the data coordinate specifiers in the using portion of the command. For each data point which has a valid set of X,Y[,Z] coordinates, the string value given to xticlabels() is added to the list of xtic labels at the same X coordinate as the point it belongs to. xticlabels() may be shortened to xtic() and so on.

Example:

     splot "data" using 2:4:6:xtic(1):ytic(3):ztic(6)

In this example the x and y axis tic labels are taken from different columns than the x and y coordinate values. The z axis tics, however, are generated from the z coordinate of the corresponding point.

Example:

     plot "data" using 1:2:xtic( $3 > 10. ? "A" : "B" )

This example shows the use of a string-valued function to generate x-axis tick labels. Each point in the data file generates a tick mark on x labeled either "A" or "B" depending on the value in column 3.

X2ticlabels See plot using xticlabels (p. 112).

Yticlabels See plot using xticlabels (p. 112).

Y2ticlabels See plot using xticlabels (p. 112).

Zticlabels See plot using xticlabels (p. 112).

Volatile

The volatile keyword indicates that the data previously read from the input stream or file may not be available for re-reading. This tells the program to use refresh rather than replot commands whenever possible. See refresh (p. 124).

Errorbars

Error bars are supported for 2D data file plots by reading one to four additional columns (or using entries); these additional values are used in different ways by the various errorbar styles.

In the default situation, gnuplot expects to see three, four, or six numbers on each line of the data file — either

     (x, y, ydelta),
     (x, y, ylow, yhigh),
     (x, y, xdelta),
     (x, y, xlow, xhigh),
     (x, y, xdelta, ydelta), or
     (x, y, xlow, xhigh, ylow, yhigh).

The x coordinate must be specified. The order of the numbers must be exactly as given above, though the using qualifier can manipulate the order and provide values for missing columns. For example,

     plot 'file' with errorbars
     plot 'file' using 1:2:(sqrt($1)) with xerrorbars
     plot 'file' using 1:2:($1-$3):($1+$3):4:5 with xyerrorbars

The last example is for a file containing an unsupported combination of relative x and absolute y errors. The using entry generates absolute x min and max from the relative error.

The y error bar is a vertical line plotted from (x, ylow) to (x, yhigh). If ydelta is specified instead of ylow and yhigh, ylow = y - ydelta and yhigh = y + ydelta are derived. If there are only two numbers on the record, yhigh and ylow are both set to y. The x error bar is a horizontal line computed in the same fashion. To get lines plotted between the data points, plot the data file twice, once with errorbars and once with lines (but remember to use the notitle option on one to avoid two entries in the key). Alternately, use the errorlines command (see errorlines (p. 114)).

The error bars have crossbars at each end unless set bars is used (see set bars (p. 133) for details).

If autoscaling is on, the ranges will be adjusted to include the error bars.

See also errorbar demos.

See plot using (p. 109), plot with (p. 120), and set style (p. 198) for more information.

Errorlines

Lines with error bars are supported for 2D data file plots by reading one to four additional columns (or using entries); these additional values are used in different ways by the various errorlines styles.

In the default situation, gnuplot expects to see three, four, or six numbers on each line of the data file — either

     (x, y, ydelta),
     (x, y, ylow, yhigh),
     (x, y, xdelta),
     (x, y, xlow, xhigh),
     (x, y, xdelta, ydelta), or
 <